Name	Initial value	Comment
cmsinfodir

Methods

• caboutdialog.userinfo - Custom method to view some user's info

  =MESSAGEBOX(cap_lbluser    +": " + m.gu_user + CHR(13) +;
      cap_lblusername+": " + m.gu_user_name,48,_SCREEN.CAPTION)
  
  

• caboutdialog.Init

  LPARAMETERS tcarg
  
  LOCAL lcbuffer, ;
      lnbuffersize, ;
      lcretval, ;
      lnreserved, ;
      lnresult, ;
      lnerror, ;
      lntype, ;
      lckey
  
  THIS.BORDERSTYLE = 2
  
  DECLARE INTEGER GetPrivateProfileString IN Win32API  AS GetPrivStr ;
      STRING  cSection   ,;
      STRING  cKey       ,;
      STRING  cDefault   ,;
      STRING  @cBuffer   ,;
      INTEGER nBufferSize,;
      STRING  cINIFile
  
  DECLARE INTEGER WritePrivateProfileString IN Win32API AS WritePrivStr ;
      STRING cSection,;
      STRING cKey    ,;
      STRING cValue  ,;
      STRING cINIFile
  
  DECLARE INTEGER RegOpenKeyEx IN Win32API ;
      INTEGER nKey       ,;
      STRING  @cSubKey   ,;
      INTEGER nReserved  ,;
      INTEGER nAccessMask,;
      INTEGER @nResult
  
  DECLARE INTEGER RegQueryValueEx IN Win32API ;
      INTEGER nKey      ,;
      STRING  cValueName,;
      INTEGER nReserved ,;
      INTEGER @nType    ,;
      STRING  @cBuffer  ,;
      INTEGER @nBufferSize
  
  DECLARE INTEGER RegCloseKey IN Win32API ;
      INTEGER nKey
  
  DECLARE INTEGER GetProfileString IN Win32API AS GetProStr ;
      STRING  cSection,;
      STRING  cKey    ,;
      STRING  cDefault,;
      STRING  @cBuffer,;
      INTEGER nBufferSize
  
  STORE 0 TO lnreserved, lnresult, lntype
  
  lcbuffer = SPACE(128)
  lnbuffersize = LEN(lcbuffer)
  
  STORE "" TO ;
      THISFORM.lblusername.CAPTION, ;
      THISFORM.lblusercorp.CAPTION, ;
      THISFORM.cmsinfodir
  
  lnerror = regopenkeyex(hkey_local_machine, key_shared_tools_location, ;
      lnreserved, key_query_value, @lnresult)
  
  IF lnerror = error_success
      lnerror = regqueryvalueex(lnresult, "PATH", lnreserved, ;
          @lntype, @lcbuffer, @lnbuffersize)
  
      IF lnerror = error_success
          THISFORM.cmsinfodir = ALLTRIM(lcbuffer)
          IF !FILE(THISFORM.cmsinfodir)
              THISFORM.cmsinfodir = ""
          ENDIF
      ENDIF
  
      =regclosekey(lnresult)
  
      lnresult = 0
      lckey = IIF("NT" $ UPPER(OS()) OR "5" $ UPPER(OS()), key_ntcurrentversion, key_win4currentversion)
      lnerror = regopenkeyex(hkey_local_machine, lckey, ;
          lnreserved, key_query_value, @lnresult)
  
      IF lnerror = error_success
          lntype = 0
          lcbuffer = SPACE(128)
          lnbuffersize = LEN(lcbuffer)
          lnerror = regqueryvalueex(lnresult, "RegisteredOwner", lnreserved, ;
              @lntype, @lcbuffer, @lnbuffersize)
  
          IF lnerror = error_success AND lcbuffer <> CHR(0)
              THISFORM.lblusername.CAPTION = LEFT(lcbuffer, lnbuffersize - 1)
          ENDIF
      ENDIF
  
      lntype = 0
      lcbuffer = SPACE(128)
      lnbuffersize = LEN(lcbuffer)
      lnerror = regqueryvalueex(lnresult, "RegisteredOrganization", lnreserved, ;
          @lntype, @lcbuffer, @lnbuffersize)
  
      IF lnerror = error_success AND lcbuffer <> CHR(0)
          THISFORM.lblusercorp.CAPTION = LEFT(lcbuffer, lnbuffersize - 1)
      ENDIF
  ENDIF
  
  =regclosekey(lnresult)
  
  IF EMPTY(THISFORM.cmsinfodir)
      THISFORM.cmsinfodir = " "
      THISFORM.cmdsysinfo.ENABLED = .F.
      THISFORM.cmdsysinfo.VISIBLE = .F.
      THISFORM.HEIGHT = THISFORM.HEIGHT - THISFORM.cmdsysinfo.HEIGHT
  ENDIF
  
  THIS.AUTOCENTER = .T.
  
  DODEFAULT(tcarg)
  
  * Read the version info from this file.
  LOCAL lainfo
  DIMENSION lainfo(12)
  IF AGETFILEVERSION(lainfo,SYS(16,0))>0
      IF NOT EMPTY(lainfo(4))
          THISFORM.lblversion.CAPTION=THISFORM.lblversion.CAPTION+ALLTRIM(lainfo[4])
      ENDIF
  ENDIF
  
  

caboutdialog.cmdOK

• caboutdialog.cmdOK.Click

  RELEASE THISFORM
  
  

caboutdialog.cmdSysInfo

• caboutdialog.cmdSysInfo.Click

  LOCAL lcmsinfowindir
  lcmsinfowindir= THISFORM.cmsinfodir
  
  RUN /n1 &lcmsinfowindir
  
  

caboutdialog.imgLogo

caboutdialog.lblAppName

caboutdialog.lblCopyright

caboutdialog.lblLicense

caboutdialog.lblTrademark

caboutdialog.lblUserCorp

caboutdialog.lblUserName

caboutdialog.lblVersion

caboutdialog.linBlackVertical

caboutdialog.linWhiteShadow

caboutdialog.shpRectangle

Name	Initial value	Comment
cpic1	bitmap\stop.bmp
cpic2	bitmap\ask.bmp
cpic3	bitmap\exclam.bmp
cpic4	bitmap\info.bmp
pnretval	.f.

Methods

• caskform.Init

  LPARAMETERS tctext, tnvalue, tctitle, tcbuttontext1, tcbuttontext2, tcbuttontext3, tltimer, tntimeout
  LOCAL lnbutton, lnpicture, lndefault, lni, lnmaxwidth, lnlines, lnheightplus, lnbuttoncount, lnbuttonwidth
  IF EMPTY(tctext)
      tctext = ""
  ENDIF
  IF EMPTY(tnvalue)
      tnvalue = 0
  ENDIF
  IF EMPTY(tctitle)
      tctitle = ""
  ENDIF
  
  IF tltimer
      THIS.TIMER.INTERVAL=tntimeout
  ENDIF
  
  lndefault        = INT(tnvalue / 256) * 256
  tnvalue            = tnvalue - lndefault
  lnpicture        = INT(tnvalue / 16) * 16
  lnbutton        = tnvalue - lnpicture
  lnmaxwidth        = 0
  lnheightplus    = 0
  lnbuttonwidth    = 80
  
  DO CASE
  CASE lnbutton = 0 OR (lnbutton = 0 AND EMPTY(tcbuttontext2))
      lnbuttoncount = 1
  CASE lnbutton = 1 OR lnbutton = 4 OR lnbutton = 5 OR ;
          (lnbutton = 6 AND EMPTY(tcbuttontext3))
      lnbuttoncount = 2
  CASE lnbutton = 2 OR lnbutton = 3 OR lnbutton = 6
      lnbuttoncount = 3
  ENDCASE
  
  WITH THISFORM
  
      .CAPTION = tctitle
  
      DO CASE
      CASE lnpicture = 16
          .imaimage.PICTURE = .cpic1
      CASE lnpicture = 32
          .imaimage.PICTURE = .cpic2
      CASE lnpicture = 48
          .imaimage.PICTURE = .cpic3
      CASE lnpicture = 64
          .imaimage.PICTURE = .cpic4
      OTHERWISE
          .imaimage.PICTURE = ""
      ENDCASE
  
      DO CASE
      CASE lndefault = 0
          .cmdbutton1.DEFAULT = .T.
      CASE lndefault = 256
          .cmdbutton2.DEFAULT = .T.
      CASE lndefault = 512
          .cmdbutton3.DEFAULT = .T.
      ENDCASE
  
      lnlines    = MEMLINES(tctext)
      FOR lni = 1 TO lnlines
          lnwidth = FONTMETRIC(6, "arial", 9) * TXTWIDTH(MLINE(tctext, lni), "arial", 9)
          IF lnwidth > lnmaxwidth
              lnmaxwidth = lnwidth
          ENDIF
      ENDFOR
  
      lnwidth = FONTMETRIC(6, "arial", 9) * TXTWIDTH(MLINE(tctitle, lni), "arial", 9)
      IF lnwidth > lnmaxwidth
          lnmaxwidth = lnwidth
      ENDIF
  
      IF lnbutton = 6
          IF !EMPTY(tcbuttontext1)
              lnbuttonwidth = FONTMETRIC(6, "arial", 9) * TXTWIDTH(STRTRAN(tcbuttontext1, "\<", ""), "arial", 9) +25
          ENDIF
          IF !EMPTY(tcbuttontext2)
              lnwidth = FONTMETRIC(6, "arial", 9) * TXTWIDTH(STRTRAN(tcbuttontext2, "\<", ""), "arial", 9) +25
              IF lnwidth > lnbuttonwidth
                  lnbuttonwidth = lnwidth
              ENDIF
          ENDIF
          IF !EMPTY(tcbuttontext3)
              lnwidth = FONTMETRIC(6, "arial", 9) * TXTWIDTH(STRTRAN(tcbuttontext3, "\<", ""), "arial", 9) +25
              IF lnwidth > lnbuttonwidth
                  lnbuttonwidth = lnwidth
              ENDIF
          ENDIF
  
          IF lnbuttonwidth > 80
              .cmdbutton1.WIDTH = lnbuttonwidth
              .cmdbutton2.WIDTH = lnbuttonwidth
              .cmdbutton3.WIDTH = lnbuttonwidth
          ELSE
              lnbuttonwidth = 80
          ENDIF
      ENDIF
  
  
      lnwidth = lnbuttonwidth * lnbuttoncount - IIF(lnbuttoncount = 1, 50, IIF(lnbuttoncount = 2, 45, 35))
      IF lnwidth > lnmaxwidth
          lnmaxwidth = lnwidth
      ENDIF
  
      IF lnlines > 2
          lnheightplus    = (lnlines -2) * FONTMETRIC(1, "arial", 9)
          .HEIGHT            = .HEIGHT + lnheightplus
          .txttext.TOP    = .txttext.TOP - 10
      ENDIF
  
      .WIDTH = MAX(lnmaxwidth + 75, 165)
  
      .txttext.WIDTH            = lnmaxwidth
      .txttext.CAPTION        = tctext
      .txttext.LEFT            = MIN((.WIDTH - 50 - lnmaxwidth) / 2 + 50, 60)
  
      .cmdbutton1.TOP            = .cmdbutton1.TOP + lnheightplus
      .cmdbutton2.TOP            = .cmdbutton2.TOP + lnheightplus
      .cmdbutton3.TOP            = .cmdbutton3.TOP + lnheightplus
  
      DO CASE
      CASE lnbutton = 0
          .cmdbutton1.VISIBLE = .T.
          .cmdbutton1.CAPTION = cap_cmdok
          .cmdbutton1.LEFT    = (.WIDTH -lnbuttonwidth) /2
      CASE lnbutton = 1
          .cmdbutton1.VISIBLE = .T.
          .cmdbutton2.VISIBLE = .T.
          .cmdbutton1.CAPTION = cap_cmdok
          .cmdbutton2.CAPTION = cap_cmdcancel
          .cmdbutton1.LEFT    = (.WIDTH -(lnbuttonwidth *2) -10) /2
          .cmdbutton2.LEFT    = .cmdbutton1.LEFT +lnbuttonwidth +10
          .cmdbutton2.CANCEL    = .T.
          .CLOSABLE            = .T.
          .lcloseonesc        = .T.
      CASE lnbutton = 2
          .cmdbutton1.VISIBLE = .T.
          .cmdbutton2.VISIBLE = .T.
          .cmdbutton3.VISIBLE = .T.
          .cmdbutton1.CAPTION = "\<"+cap_cmdabort
          .cmdbutton2.CAPTION = "\<"+cap_cmdretry
          .cmdbutton3.CAPTION = "\<"+cap_cmdignore
          .cmdbutton1.LEFT    = (.WIDTH -(lnbuttonwidth *3) -20) /2
          .cmdbutton2.LEFT    = .cmdbutton1.LEFT +lnbuttonwidth +10
          .cmdbutton3.LEFT    = .cmdbutton2.LEFT +lnbuttonwidth +10
      CASE lnbutton = 3
          .cmdbutton1.VISIBLE = .T.
          .cmdbutton2.VISIBLE = .T.
          .cmdbutton3.VISIBLE = .T.
          .cmdbutton1.CAPTION = "\<"+cap_cmdyes
          .cmdbutton2.CAPTION = "\<"+cap_cmdno
          .cmdbutton3.CAPTION = cap_cmdcancel
          .cmdbutton1.LEFT    = (.WIDTH -(lnbuttonwidth *3) -20) /2
          .cmdbutton2.LEFT    = .cmdbutton1.LEFT +lnbuttonwidth +10
          .cmdbutton3.LEFT    = .cmdbutton2.LEFT +lnbuttonwidth +10
          .cmdbutton3.CANCEL    = .T.
          .CLOSABLE            = .T.
          .lcloseonesc        = .T.
      CASE lnbutton = 4
          .cmdbutton1.VISIBLE = .T.
          .cmdbutton2.VISIBLE = .T.
          .cmdbutton1.CAPTION = "\<"+cap_cmdyes
          .cmdbutton2.CAPTION = "\<"+cap_cmdno
          .cmdbutton1.LEFT    = (.WIDTH -(lnbuttonwidth *2) -10) /2
          .cmdbutton2.LEFT    = .cmdbutton1.LEFT +lnbuttonwidth +10
      CASE lnbutton = 5
          .cmdbutton1.VISIBLE = .T.
          .cmdbutton2.VISIBLE = .T.
          .cmdbutton1.CAPTION = "\<"+cap_cmdretry
          .cmdbutton2.CAPTION = cap_cmdcancel
          .cmdbutton1.LEFT    = (.WIDTH -(lnbuttonwidth *2) -10) /2
          .cmdbutton2.LEFT    = .cmdbutton1.LEFT +lnbuttonwidth +10
          .cmdbutton2.CANCEL    = .T.
          .CLOSABLE            = .T.
          .lcloseonesc        = .T.
      CASE lnbutton = 6
          IF !EMPTY(tcbuttontext1)
              .cmdbutton1.VISIBLE = .T.
              .cmdbutton1.CAPTION = tcbuttontext1
              .cmdbutton1.LEFT    = (.WIDTH -lnbuttonwidth) /2
              IF LOWER(tcbuttontext1) = LOWER(cap_cmdcancel)
                  .cmdbutton1.CANCEL    = .T.
                  .CLOSABLE            = .T.
                  .lcloseonesc        = .T.
              ENDIF
          ELSE
              RETURN .F.
          ENDIF
          IF !EMPTY(tcbuttontext2)
              .cmdbutton2.VISIBLE = .T.
              .cmdbutton2.CAPTION = tcbuttontext2
              .cmdbutton1.LEFT    = (.WIDTH -(lnbuttonwidth *2) -10) /2
              .cmdbutton2.LEFT    = .cmdbutton1.LEFT +lnbuttonwidth +10
              IF LOWER(tcbuttontext2) = LOWER(cap_cmdcancel)
                  .cmdbutton2.CANCEL    = .T.
                  .CLOSABLE            = .T.
                  .lcloseonesc        = .T.
              ENDIF
          ENDIF
          IF !EMPTY(tcbuttontext3)
              .cmdbutton3.VISIBLE = .T.
              .cmdbutton3.CAPTION = tcbuttontext3
              .cmdbutton1.LEFT    = (.WIDTH -(lnbuttonwidth *3) -20) /2
              .cmdbutton2.LEFT    = .cmdbutton1.LEFT +lnbuttonwidth +10
              .cmdbutton3.LEFT    = .cmdbutton2.LEFT +lnbuttonwidth +10
              IF LOWER(tcbuttontext3) = LOWER(cap_cmdcancel)
                  .cmdbutton3.CANCEL    = .T.
                  .CLOSABLE            = .T.
                  .lcloseonesc        = .T.
              ENDIF
          ENDIF
      OTHERWISE
          RETURN .F.
      ENDCASE
  
  ENDWITH
  
  RETURN DODEFAULT()
  
  

• caskform.Show

  LPARAMETERS nstyle
  
  WITH THISFORM
      DO CASE
      CASE .cmdbutton1.DEFAULT
          .cmdbutton1.SETFOCUS()
      CASE .cmdbutton2.DEFAULT
          .cmdbutton2.SETFOCUS()
      CASE .cmdbutton3.DEFAULT
          .cmdbutton3.SETFOCUS()
      ENDCASE
  ENDWITH
  
  

• caskform.Unload

  RETURN THIS.pnretval
  
  

caskform.cmdbutton1

• caskform.cmdbutton1.Click

  THISFORM.pnretval = 1
  THISFORM.RELEASE()
  
  

caskform.cmdbutton2

• caskform.cmdbutton2.Click

  THISFORM.pnretval = 2
  THISFORM.RELEASE()
  
  

caskform.cmdbutton3

• caskform.cmdbutton3.Click

  THISFORM.pnretval = 3
  THISFORM.RELEASE()
  
  

caskform.imaImage

caskform.txtText

caskform.timer

• caskform.timer.Timer

  THISFORM.cmdbutton1.CLICK()
  
  

• caudittrail.Init

  LPARAMETERS tccaption, tcaudit
  
  THIS.CAPTION = tccaption
  THIS.edtaudit.VALUE = tcaudit
  
  RETURN DODEFAULT()
  
  

caudittrail.edtAudit

Name	Initial value	Comment
cerror	.f.
oparentdate	.f.	Date Textbox from where this Form has been called

Methods

• ccalendar.getdate - Gets the Date from the OLE Calendar

  LOCAL lcday, lcmonth, lcyear, lcdate, lddate, lcolddate
  
  * Get the Date Values
  WITH THISFORM.olecalendar
      lcday = ALLTRIM(STR(.DAY()))
      lcmonth = ALLTRIM(STR(.MONTH()))
      lcyear = ALLTRIM(STR(.YEAR()))
  ENDWITH
  
  * String to Date Conversion
  lcolddate = SET("date")
  SET DATE TO GERMAN
  lcdate = lcday + "." + lcmonth + "." + lcyear
  lddate = CTOD(lcdate)
  SET DATE TO &lcolddate
  
  RETURN lddate
  
  

• ccalendar.setdate - Sets the OLE-Calendar's Date

  LOCAL lddate
  
  WITH THISFORM
  
      IF !EMPTY(NVL(.oparentdate.txtdate.VALUE, {}))
          lddate = .oparentdate.txtdate.VALUE
          .olecalendar.DAY = DAY(lddate )
          .olecalendar.MONTH = MONTH(lddate )
          .olecalendar.YEAR = YEAR(lddate )
      ELSE
          lddate = DATE()
          .olecalendar.DAY = DAY(lddate)
          .olecalendar.MONTH = MONTH(lddate)
          .olecalendar.YEAR = YEAR(lddate)
      ENDIF
  
  ENDWITH
  
  

• ccalendar.Init

  LPARAMETERS toparentdate
  DODEFAULT()
  
  THIS.oparentdate = toparentdate
  
  IF (!EMPTY(toparentdate.cpicktext))
      THIS.CAPTION = toparentdate.cpicktext
  ENDIF
  
  IF (toparentdate.isdmydate)
      THISFORM.setdate()
  ENDIF
  
  

• ccalendar.langsetup

  **__VFX_WIZARD_HEADER  - 29.08.1998 23:14:49
  
  thisform.cmdapply.Caption = CAP_CMDAPPLY
  thisform.cmdclose.Caption = CAP_CMDCANCEL
  thisform.cmdok.Caption = CAP_CMDOK
  
  return .T.
  **__VFX_WIZARD_FOOTER
  ***********************************************************
  
  
  

ccalendar.cmdApply

• ccalendar.cmdApply.Click

  * Just update the Value in the ParentDate - Object
  WITH THISFORM
      IF (TYPE("thisform.oParentDate") = "O")
  
          LOCAL lddate
          lddate    = .getdate()
  
          IF VARTYPE(THISFORM.oparentdate.txtdate.VALUE)$"DTX"
              IF NVL(.oparentdate.txtdate.VALUE, {}) != lddate
                  * switch to edit mode if neccessary
                  .oparentdate.setdate(lddate)
                  IF .oparentdate.lautosetup
                      .oparentdate.txtdate.INTERACTIVECHANGE()
                  ENDIF
              ENDIF
          ENDIF
      ENDIF
  ENDWITH
  
  

ccalendar.cmdClose

• ccalendar.cmdClose.Click

  * close the form without update
  
  THISFORM.RELEASE
  
  

ccalendar.cmdOk

• ccalendar.cmdOk.Click

  * Update the Value and close the form
  
  WITH THISFORM
      .cmdapply.CLICK()
      .cmdclose.CLICK()
  ENDWITH
  
  

ccalendar.OLECalendar

• ccalendar.OLECalendar.DblClick

  *** OLE Control Event ***
  THISFORM.cmdok.CLICK()
  NODEFAULT
  
  

• ccalendar.OLECalendar.KeyPress

  *** OLE Control Event ***
  LPARAMETERS keyascii
  
  * inform buttons about keypress
  DO CASE
  CASE keyascii = 27    && ESCAPE
      THISFORM.cmdclose.CLICK()
  CASE keyascii = 13    && ENTER
      THISFORM.cmdok.CLICK()
  ENDCASE
  
  

• cdatabasetools.doit - Execute database functions on selected item

  LOCAL lnitem, lnmaxitems, lctablename, latable[1,4],logauge
  
  ** If using SDT the goProgram.cMainDatabase property must be the same DBC
  ** that SDT's Meta data is based on
  
  IF !THISFORM.cntmover.GETDATA(@latable)
      RETURN .F.
  ENDIF
  
  lnmaxitems = ALEN(latable,1)
  
  logauge = CREATEOBJECT('CGaugeWin', lnmaxitems)
  
  logauge.SHOW()
  
  LOCAL llsdt
  
  llsdt = .F.
  
  #ifdef _stonefield
  LOCAL lquiet
  llsdt = .T.
  lquiet = ometa.osdtmgr.lquiet
  ometa.osdtmgr.lquiet = .T.
  #ENDIF
  
  IF ADIR(ladummy,goprogram.cvfxdir+"vfxres.dbf")#1
      IF ADIR(ladummy,goprogram.cdatadir+"\vfxres.dbf")#1
          * Table not found. Create new table.
          THIS.createtable(goprogram.cvfxdir+"vfxres")
      ENDIF
  ENDIF
  USE vfxres EXCLUSIVE
  
  IF ISEXCLUSIVE()
      PACK
  ENDIF
  
  IF ADIR(ladummy,goprogram.cvfxdir+"vfxlock.dbf")#1
      IF ADIR(ladummy,goprogram.cdatadir+"\vfxlock.dbf")#1
          * Table not found. Create new table.
          THIS.createtable(goprogram.cvfxdir+"vfxlock")
      ENDIF
  ENDIF
  USE vfxlock EXCLUSIVE
  
  IF ISEXCLUSIVE()
      PACK
  ENDIF
  
  IF ADIR(ladummy,goprogram.cvfxdir+"vfxlog.dbf")#1
      IF ADIR(ladummy,goprogram.cdatadir+"\vfxlog.dbf")#1
          * Table not found. Create new table.
          THIS.createtable(goprogram.cvfxdir+"vfxlog")
      ENDIF
  ENDIF
  USE vfxlog EXCLUSIVE
  
  IF ISEXCLUSIVE()
      PACK
  ENDIF
  
  USE
  
  FOR lnitem = 1 TO lnmaxitems
  
      logauge.setvalue(lnitem)
  
      lctablename = ALLTRIM(latable[lnItem,1])
  
      IF THISFORM.chkrepair.VALUE
          logauge.settext("Repair: " + lctablename)
  
          IF  latable[lnItem,4]
              ometa.osdtmgr.repair(lctablename)
          ENDIF
      ELSE
          USE (goprogram.cdatadir+"\"+lctablename) IN 0 EXCLUSIVE
  
          IF !ISEXCLUSIVE(lctablename)
              =MESSAGEBOX(msg_table_lock_error,;
                  mb_ok+mb_iconstop  ,;
                  lctablename)
          ELSE
              SELECT (lctablename)
  
              DO CASE
              CASE THISFORM.chkpack.VALUE
                  logauge.settext("Packing: " + lctablename)
                  IF latable[lnItem,4] AND llsdt
                      USE IN (lctablename)
                      ometa.osdtmgr.REINDEX(lctablename,.T.)
                  ELSE
                      PACK
                  ENDIF
  
              CASE THISFORM.chkpackmemo.VALUE
                  logauge.settext("Packing Memo: " + lctablename)
                  PACK MEMO
  
              CASE THISFORM.chkreindex.VALUE
                  logauge.settext("Reindex: " + lctablename)
                  IF latable[lnItem,4] AND llsdt
                      USE IN (lctablename)
                      ometa.osdtmgr.REINDEX(lctablename,.F.)
                  ELSE
                      REINDEX
                  ENDIF
              ENDCASE
          ENDIF    && !exclusive()
      ENDIF    && chkRepair
  
      IF USED(lctablename)
          USE IN (lctablename)
      ENDIF
  NEXT
  
  #ifdef _stonefield
  ometa.osdtmgr.lquiet = lquiet
  #ENDIF
  
  logauge=.NULL.
  RELEASE logauge
  
  CLOSE TABLES ALL
  
  WAIT CLEAR
  
  

• cdatabasetools.langsetup

  **__VFX_WIZARD_HEADER  - 08/07/96 04:28:15 PM
  
  thisForm.Caption = CAP_FRMDATABASETOOLS
  thisform.cntmover.lblsource.Caption = CAP_LBLTABLES
  thisform.cntmover.lblselected.Caption = CAP_LBLSELECTED
  thisform.lblrecords.Caption = CAP_LBLRECORDS
  thisform.chkpack.Caption = CAP_PACK
  thisform.chkrepair.Caption = CAP_REPAIR
  thisform.chkpackmemo.Caption = CAP_PACKMEMO
  thisform.chkreindex.Caption = CAP_REINDEX
  thisform.cmdok.Caption = CAP_CMDOK
  thisform.cmdclose.Caption = CAP_CMDCANCEL
  
  return .T.
  **__VFX_WIZARD_FOOTER
  ***********************************************************
  
  
  

• cdatabasetools.Destroy

  SET DATASESSION TO 1
  
  CLOSE DATA ALL
  
  goprogram.opendatabase()
  
  RETURN DODEFAULT()
  
  

• cdatabasetools.Init

  LPARAMETERS tcarg
  
  ** If using SDT the goProgram.cMainDatabase property must be the same DBC
  ** that SDT's Meta data is based on
  
  LOCAL latable[1,1],lnitem, logauge, lafiles[1,1], lctable, lcdata, lnhowmany
  
  IF TYPE("goProgram") # "O"
      RETURN .F.
  ENDIF
  
  IF goprogram.nformcount <> 0
      =MESSAGEBOX(msg_windows_opened,0+48,_SCREEN.CAPTION)
      RETURN .F.
  ENDIF
  
  IF ADIR(lafiles, goprogram.cdatadir+"\*.DBF","A") = 0
      RETURN .F.
  ENDIF
  
  #ifdef _stonefield
  THIS.chkrepair.VISIBLE = .T.
  THIS.chkrepair.ENABLED = .T.
  #ELSE
      THIS.chkrepair.VISIBLE = .F.
      THIS.chkrepair.ENABLED = .F.
  #ENDIF
  
  SET DATASESSION TO 1
  
  CLOSE DATA ALL
  
  *!*    The database must be opened exclusive.
  IF !goprogram.opendatabase(.T.)
      RETURN .F.
  ENDIF
  
  ** Exclude some tables
  
  LOCAL lctemp, lnindex
  
  lnhowmany = getargcount(goprogram.cexcludefiles)
  
  FOR j = 1 TO lnhowmany
      lctemp = UPPER(getarg(goprogram.cexcludefiles,j))
  
      lnindex = ASCAN(lafiles,lctemp)
  
      IF lnindex # 0
          lnindex = ASUBSCRIPT(lafiles, lnindex, 1)
          lafiles[lnIndex,1] = ''
      ENDIF
  NEXT
  
  =ASORT(lafiles)
  
  THIS.AUTOCENTER = .T.
  
  DODEFAULT(tcarg)
  
  THIS.WIDTH  = THIS.WIDTH
  THIS.HEIGHT = THIS.HEIGHT
  
  logauge = CREATEOBJECT('CGaugeWin', ALEN(lafiles,1), msg_working)
  
  logauge.SHOW()
  
  * Load Tables description
  
  DIMENSION latable[ALEN(laFiles,1),4]
  
  * 1 - TableName
  * 2 - Capion
  * 3 - Records
  * 4 - in goProgram.cMainDatabase
  FOR lnitem = 1 TO ALEN(lafiles,1)
  
      logauge.setvalue(lnitem)
  
      IF !EMPTY(lafiles[lnItem,1])
          lcdata  = ALLTRIM(STRTRAN(UPPER(lafiles[lnItem,1]),".DBF",""))
          lctable = ''
  
          latable[lnItem,4] = INDBC(lcdata,'TABLE')
  
          IF latable[lnItem,4]
              lctable = DBGETPROP(lcdata,'TABLE','COMMENT')
          ENDIF
  
          IF EMPTY(lctable)
              lctable = UPPER(lcdata)
          ENDIF
  
          latable[lnItem,1] = lcdata
          latable[lnItem,2] = lctable
  
          logauge.settext("Loading: " + lcdata)
  
          lctable = goprogram.cdatadir+ "\" + ALLTRIM(lcdata)
  
          USE (lctable) IN 0 ALIAS _vfx_table
  
          latable[lnItem,3] = RECCOUNT("_VFX_TABLE")
  
          USE IN _vfx_table
      ENDIF
  NEXT
  
  logauge.RELEASE()
  
  THIS.cntmover.SETDATA(@latable)
  
  

• cdatabasetools.Activate

  DODEFAULT()
  THIS.cntmover.SETFOCUS()
  
  

• cdatabasetools.Error

  LPARAMETERS nerror, cmethod, nline
  
  IF nerror = 1705 OR nerror = 13
      RETURN .F.
  ENDIF
  
  

cdatabasetools.chkPack

• cdatabasetools.chkPack.When

  RETURN THIS.PARENT.cntmover.lstselected.LISTCOUNT  > 0
  
  

• cdatabasetools.chkPack.Click

  THISFORM.dispbegin()
  
  IF THIS.VALUE = .T.
      THISFORM.chkpackmemo.VALUE = .T.
      THISFORM.chkreindex.VALUE  = .T.
  
      THISFORM.chkpackmemo.ENABLED = .F.
      THISFORM.chkreindex.ENABLED  = .F.
  ELSE
      THISFORM.chkpackmemo.ENABLED = .T.
      THISFORM.chkreindex.ENABLED  = .T.
  ENDIF
  
  THISFORM.cmdok.REFRESH()
  
  THISFORM.dispend()
  
  

cdatabasetools.chkPackMemo

• cdatabasetools.chkPackMemo.When

  RETURN THIS.PARENT.cntmover.lstselected.LISTCOUNT  > 0
  
  

• cdatabasetools.chkPackMemo.Click

  THISFORM.cmdok.REFRESH()
  
  

cdatabasetools.chkReindex

• cdatabasetools.chkReindex.When

  RETURN THIS.PARENT.cntmover.lstselected.LISTCOUNT  > 0
  
  

• cdatabasetools.chkReindex.Click

  THISFORM.cmdok.REFRESH()
  
  

cdatabasetools.chkRepair

• cdatabasetools.chkRepair.When

  RETURN THIS.PARENT.cntmover.lstselected.LISTCOUNT  > 0
  
  

• cdatabasetools.chkRepair.Click

  THISFORM.dispbegin()
  
  IF THIS.VALUE = .T.
      THISFORM.chkpack.VALUE     = .F.
      THISFORM.chkpackmemo.VALUE = .F.
      THISFORM.chkreindex.VALUE  = .F.
  
      THISFORM.chkpack.ENABLED     = .F.
      THISFORM.chkpackmemo.ENABLED = .F.
      THISFORM.chkreindex.ENABLED  = .F.
  ELSE
      THISFORM.chkpack.ENABLED     = .T.
      THISFORM.chkpackmemo.ENABLED = .T.
      THISFORM.chkreindex.ENABLED  = .T.
  ENDIF
  
  THISFORM.cmdok.REFRESH()
  
  THISFORM.dispend()
  
  

cdatabasetools.cmdClose

• cdatabasetools.cmdClose.Click

  THISFORM.RELEASE()
  
  

cdatabasetools.cmdOK

• cdatabasetools.cmdOK.Click

  THISFORM.doit()
  THISFORM.RELEASE()
  
  

cdatabasetools.cntMover

• cdatabasetools.cntMover.onsourcechange

  THISFORM.txtrecords.VALUE = THIS.LIST[this.SourceListIndex,3]
  THISFORM.edtcomment.VALUE = THIS.LIST[this.SourceListIndex,2]
  
  

• cdatabasetools.cntMover.onselectedchange

  THISFORM.txtrecords.VALUE = THIS.LIST[this.ListIndex,3]
  THISFORM.edtcomment.VALUE = THIS.LIST[this.ListIndex,2]
  
  

cdatabasetools.cntMover.cmdAdd

cdatabasetools.cntMover.cmdAddAll

cdatabasetools.cntMover.cmdRemove

cdatabasetools.cntMover.cmdRemoveAll

cdatabasetools.cntMover.lblSelected

cdatabasetools.cntMover.lblSource

cdatabasetools.cntMover.lstSelected

• cdatabasetools.cntMover.lstSelected.Refresh

  THISFORM.cmdok.REFRESH()
  
  DODEFAULT()
  
  

cdatabasetools.cntMover.lstSource

cdatabasetools.edtComment

• cdatabasetools.edtComment.Init

  DODEFAULT()
  
  LOCAL lnbackcolor
  
  DECLARE INTEGER GetSysColor IN Win32API INTEGER nColorIndex
  lnbackcolor = getsyscolor(15)
  
  THIS.DISABLEDBACKCOLOR = lnbackcolor
  
  

cdatabasetools.lblRecords

cdatabasetools.Cshape1

cdatabasetools.txtRecords

Name	Initial value	Comment
^aindexsave[1,2]	.f.	Store the original tag for each tables
^atempcursor[1,0]	.f.	Reserved. array of temporary cursor
ccalledby		Stores the name of the parent form. Used when parent child forms are used.
cemptymessage		Specifies the alternate message to show when the form is empty
cfavoritedescr	.f.	Fieldname from the record which is used to name the favorite (usually table.fieldname)
cfavoriteid		Identification Expression to locate the record (usually table.fieldname). If empty, according Primary key automatically evaluated. NOTE: Must be set when working with views, since no PK can be evaluated automatically!
cfavoritemenu	.f.	The caption of the menu-entry for the favorites-menu as to name the favorites entries for this form
cfilterexpr		Current filter expression for this form
cfixfieldname		Name of the parent field in 1-many situations. This is the the parent table's primary key which will be used as a foreign key within the child form.
cfixfieldvalue		Value of the parent field in 1-many situations. This is the value of the primary key of the parent form.
cidxmgrclass	CIDXManager	Name of an alternate idxmaneger class
coldtitle		Old title of the form.
cqueryarg	.f.	View Argument. Each argument must be separated with ; By default 5 arguments are handled in the init() template code of the child form. Type: Char!
crecordmgrclass	CDataTableMgr	Alternate name of the record manager class
creportname		Specifies the report to run when user clicks on Print/Preview
csearchfilterexpr		Reserved. search filter returned by search dialog.
csearchform	VFXSRCH	Ssearch dialog to be used. Default: vfxsrch
csetkeyexpr	.f.	Specifies the expression wich is used for the "set key" scenario.
csetkeyindex	.f.	Specifies the tag to be used as master index when SET KEY is used
csetkeyvalue	.f.	Specifies the value to be used in the SET KEY command
ctempindex		Reserved. temporary index expression.
cviewindexexpr		Index expression for a local o remote view.
cworkalias		Alias of the master table. By default this is data enviroment "initialselectedalias"
cworktag		Reserved. initial master tag.
event.	.f.
lactcanedit	.f.	Stores the actual setting of the lcanedit property. The lcanedit property will be switched temporarily to .t. when inserting a record.
lasktosave	.T.	Specifies if when you are in insert mode and recall an insert, a confirm dialog will be displayed
laudit	.f.	Defined whether you want audit trail to be activated.
lautoedit	.T.	Specifies if the form will automatically switch to edit mode when a user starts modifying whatever control on the form.
lcancopy	.T.	In the previous version, the copy feature was "related" to the edit feature in terms of permission/availability. Now, the permission/availability of the copy process can be defined independently from the edit process.
lcandelete	.T.	Security/permissen setting for deleting: .t. if user can delete
lcanedit	.T.	Security/permissen setting for editing: .t. if user can edit
lcaninsert	.T.	Security/permissen setting for inserting: .t. if user can insert new records
lchildform	.f.	Specifies if this form is a child Form
ldonotaskondelete	.f.	With the properties ldonotaskondelete and lSupressMessageondelete the programmer can define, whether to display the standard VFX messageboxes prior and after deletion or whether he prefers showing his own in the onpostdelete event.
lempty	.T.	Reserved. .t. if database is empty. Be cautios when overwriting this property. Make also sure to call onemptyform when changing manually!
lfilteron	.f.	Reserved. .t. if there is an active filter.
lhidewhenempty	.T.	Defines whether the edit page will be hidden when no record exists.
lmore	.f.	Defines whether there are more functions to be called (F6). See also the onmore method.
lonsearchusegrid	.f.	Defines whether only the fields available within the standard grid are available for searching or not.
lrestoreidx	.T.	Specifies if the IDX will be restored automatically when form restarts.
lsuppressmessageondelete	.f.	With the properties ldonotaskondelete and lSupressMessageondelete he programmer can define, whether to display the standard VFX messageboxes prior and after deletion or whether he prefers showing his own in the onpostdelete
lusesetkeyasfilter	.f.	Specifies if iSET KEY has to be used as filtering mechanism rather than the SET FILTER TO command directly. Performance may dictate this. NOTE: SET FILTER TO looses rushmore optimization when used in a standard VFP not VFX (!) form :-(
lworkonview	.f.	Client/Server mode: .t. if data is a view (local or remote)
nformstatus	0	Describes the status of the form. 0 = Normal, 1 = Edit, 2 = Insert
noldrecno	0	Reserved. Old record.
nwarninglevel	0	0 - if update conflict only a simple message. 1- field by field message
ofields	.f.	Used to copy a record.
opickfield	.NULL.	Reserved. Stores the pointer to a Pick Field

Methods

• cdataform.clearidx - Close and erase all temporary index files for the current form. See also: cfoxapp method clearallidx.

  LOCAL lcindex, lcalias, lcrelation, lnrecno, j, lcleared, ;
      latables[1], laindexes[1], k, lctable
  
  IF EMPTY(THISFORM.cworkalias)
      RETURN .F.
  ENDIF
  
  FOR j = 1 TO THISFORM.CONTROLCOUNT
      IF LOWER(THISFORM.CONTROLS[j].BASECLASS) = 'grid'
          THISFORM.CONTROLS[j].SETALL('Tag','','TextBox')
      ENDIF
  NEXT
  
  SELECT (THISFORM.cworkalias)
  
  lnrecno    = IIF(EOF() OR DELETED(), 0, RECNO())
  
  ** This crashes under Windows NT 4.0 !!!!!!!
  *lcRelation = set('RELATION')
  
  lcrelation = vfx_getrelation()
  
  ** Clear all Temporary Indexes
  
  THISFORM.oidxmanager.CLEAR()
  
  ** Reset Original Alias/Tag
  
  THISFORM.oidxmanager.restoretag()
  
  SELECT (THISFORM.cworkalias)
  SET ORDER TO TAG (THISFORM.cworktag)
  
  IF !EMPTY(lcrelation)
      SET RELATION TO &lcrelation
  ENDIF
  
  THISFORM.setkeyreset()
  
  WAIT CLEAR
  
  

• cdataform.errorhandler - Error handler for table rules like: fielderror, recorderror, triggererror, updateerror, uniqueerror and odbcerror

  LPARAMETERS tnerror
  
  LOCAL llhandled
  
  THISFORM.dispend(.T.)
  
  llhandled = .T.
  
  DO CASE
  CASE tnerror = error_field_rule_violated
      THISFORM.fielderror()
  
  CASE tnerror = error_record_rule_violated
      THISFORM.recorderror()
  
  CASE tnerror = error_trigger_failed
      THISFORM.triggererror()
  
  CASE tnerror = error_update_conflict
      THISFORM.updateerror()
  
  CASE tnerror = error_unique_index_violated
      THISFORM.uniqueerror()
  
  CASE tnerror = error_connectivity_error
      THISFORM.odbcerror()
  
  OTHERWISE
      llhandled = .F.
  
  ENDCASE
  
  RETURN llhandled
  
  

• cdataform.fielderror - Called by the form's errorhandler when field trigger is violated.

  LOCAL laerror[7],lcfield, lcmessage, lccaption
  
  lcmessage = ""
  
  =AERROR(laerror)
  
  lcmessage = laerror[2]
  lccaption = msg_bad_input
  
  DO CASE
  CASE laerror[5] = 1
      lccaption = "Insert Error"
  CASE laerror[5] = 2
      lccaption = "Update Error"
  CASE laerror[5] = 3
      lccaption = "Delete Error"
  ENDCASE
  
  IF !EMPTY(lcmessage)
      =MESSAGEBOX(lccaption + CHR(13) + lcmessage,mb_ok+mb_iconstop,msg_attention)
  ENDIF
  
  

• cdataform.odbcerror - Called by the form's errorhandler when odbc trigger is violated

  LOCAL laerror[7]
  
  =AERROR(laerror)
  
  =MESSAGEBOX("ODBC Error: "   + TRANSFORM(laerror[5]) +CHR(13)+;
      "odbc message: " + laerror[3]       +CHR(13)+CHR(13)+;
      "message: "      + laerror[2],64,"ODBC ERROR")
  
  

• cdataform.onbottom - Called when you go bottom

  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnBottom",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  IF THISFORM.nformstatus <> id_normal_mode
      IF THISFORM.recordchanged() OR THISFORM.nformstatus = id_insert_mode
          IF !THISFORM.asktosave()
              ** Do Nothing
              RETURN .F.
          ENDIF
      ELSE
          THISFORM.onundo()
      ENDIF
  ENDIF
  
  SELECT (THISFORM.cworkalias)
  
  THISFORM.orecord.gobottom()
  
  THISFORM.onrecordmove()
  
  THISFORM.REFRESH()
  
  

• cdataform.ondelete - Called when you delete a record

  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnDelete",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  SELECT (THISFORM.cworkalias)
  
  IF !THISFORM.lcandelete
      WAIT WINDOW msg_cant_delete
      RETURN .F.
  ENDIF
  
  THISFORM.noldrecno = IIF(EOF() OR DELETED(), 0, RECNO())
  
  LOCAL lldeleteok
  lldeleteok = .F.
  
  IF !THISFORM.lempty
      IF THISFORM.ldonotaskondelete .OR. ;
              MESSAGEBOX(msg_ask_delete,mb_yesno+mb_iconquestion+mb_defbutton2,msg_attention) = idyes
          SELECT (THISFORM.cworkalias)
  
          IF VARTYPE(goProgram)="O"
              IF !goprogram.lnoclearidxondelete
                  goprogram.clearallidx()
              ENDIF
          ELSE
              THISFORM.clearidx()
          ENDIF
  
          IF THISFORM.onpredelete()
  
              SELECT (THISFORM.cworkalias)
  
              IF THISFORM.orecord.DELETE()
                  IF THISFORM.onpostdelete()
                      SELECT (THISFORM.cworkalias)
                      IF TABLEUPDATE(.T.,.T.)
                          lldeleteok = .T.
                          IF EOF()
                              THISFORM.orecord.gotop()
                          ELSE
                              THISFORM.orecord.NEXT()
                              IF EOF()
                                  THISFORM.orecord.gobottom()
                              ENDIF
                          ENDIF
                      ELSE
                          SELECT (THISFORM.cworkalias)
                          IF !THISFORM.lsuppressmessageondelete
                              = MESSAGEBOX(msg_not_deleted,mb_ok+mb_iconstop,msg_attention)
                          ENDIF
                          = TABLEREVERT(.T.)
                      ENDIF
                  ELSE
                      SELECT (THISFORM.cworkalias)
                      IF !THISFORM.lsuppressmessageondelete
                          =MESSAGEBOX(msg_not_deleted,mb_ok+mb_iconstop,msg_attention)
                      ENDIF
                      =TABLEREVERT(.T.)
                  ENDIF
              ELSE
                  SELECT (THISFORM.cworkalias)
                  IF !THISFORM.lsuppressmessageondelete
                      =MESSAGEBOX(msg_not_deleted,mb_ok+mb_iconstop,msg_attention)
                  ENDIF
              ENDIF
          ELSE
              lldeleteok = .F.
          ENDIF
      ELSE
          lldeleteok = .F.
      ENDIF
  ENDIF
  SELECT (THISFORM.cworkalias)
  
  IF lldeleteok
      IF VARTYPE(goProgram)="O" AND goprogram.lremakeidxafterclear
          THISFORM.remakeidx("D")
          THISFORM.noldrecno = -1
      ENDIF
  ENDIF
  
  THISFORM.onrecordmove()
  
  THISFORM.refreshtoolbar(.T.)
  THISFORM.REFRESH()
  
  RETURN lldeleteok
  
  

• cdataform.onedit - Called when you edit a record

  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnEdit",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  LOCAL lbypass
  
  lbypass = THISFORM.nformstatus # 1
  
  SELECT (THISFORM.cworkalias)
  
  THISFORM.noldrecno = IIF(EOF() OR DELETED(), 0, RECNO())
  
  IF DELETED()
      =MESSAGEBOX(msg_record_deleted_from_others,48,THISFORM.CAPTION)
  
      THISFORM.orecord.gotop()
  
      THISFORM.onrecordmove()
  
      THISFORM.REFRESH()
  
      RETURN .F.
  ENDIF
  
  IF !THISFORM.lcanedit
      WAIT WINDOW msg_cant_edit
      THISFORM.onundo()
      RETURN .F.
  ENDIF
  
  THIS.lactcanedit = THIS.lcanedit
  
  IF !THISFORM.lempty
      IF THISFORM.onpreedit()
          SELECT (THISFORM.cworkalias)
  
          IF VARTYPE(goProgram)="O"
              IF !goprogram.lnoclearidxonedit
                  goprogram.clearallidx()
              ENDIF
          ELSE
              THISFORM.clearidx()
          ENDIF
  
          IF THISFORM.nformstatus != 0 AND !EMPTY(THISFORM.coldtitle)
              THISFORM.CAPTION = THISFORM.coldtitle
          ENDIF
  
          THISFORM.nformstatus = id_edit_mode
  
          THISFORM.coldtitle = THISFORM.CAPTION
  
          THISFORM.CAPTION = msg_editmode + " " + ALLTRIM(THISFORM.CAPTION)
  
          THISFORM.refreshtoolbar(.T.)
  
          THISFORM.onformstatuschange()
  
          IF lbypass
              THISFORM.REFRESH()
              THISFORM.setobjectfocus()
          ENDIF
      ELSE
          THISFORM.onundo()
          RETURN .F.
      ENDIF
  ENDIF
  
  

• cdataform.oninsert - Called when you insert new record

  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnInsert",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  SELECT (THISFORM.cworkalias)
  
  IF !THISFORM.lcaninsert
      WAIT WINDOW msg_cant_insert
      RETURN .F.
  ENDIF
  
  IF THISFORM.nformstatus <> id_normal_mode
      IF !THISFORM.asktosave()
          ** Do Nothing
          RETURN .F.
      ENDIF
  
      THISFORM.nformstatus = id_normal_mode
      THISFORM.CAPTION = THISFORM.coldtitle
      THISFORM.refreshtoolbar(.T.)
      THISFORM.onformstatuschange()
      THISFORM.REFRESH()
  ENDIF
  
  THIS.lactcanedit = THIS.lcanedit
  THIS.lcanedit = .T.
  
  LOCAL lnrecno
  
  lnrecno = IIF(EOF() OR DELETED(), 0, RECNO())
  
  THISFORM.noldrecno = lnrecno
  
  IF THISFORM.onpreinsert()
      SELECT (THISFORM.cworkalias)
  
      IF VARTYPE(goProgram)="O"
          IF !goprogram.lnoclearidxoninsert
              goprogram.clearallidx()
          ENDIF
      ELSE
          THISFORM.clearidx()
      ENDIF
  
      SELECT (THISFORM.cworkalias)
  
      THISFORM.orecord.INSERT()
  
      ** Check the Active control
      IF TYPE("thisForm.ActiveControl")="O"
          LOCAL locontrol
  
          locontrol = THISFORM.ACTIVECONTROL
  
          IF LOWER(locontrol.BASECLASS) == "grid"
              locontrol.REFRESH()
          ENDIF
      ENDIF
  
      IF THISFORM.nformstatus != 0 AND !EMPTY(THISFORM.coldtitle)
          THISFORM.CAPTION = THISFORM.coldtitle
      ENDIF
  
      THISFORM.nformstatus = id_insert_mode
  
      IF !THISFORM.onpostinsert()
          THISFORM.onundo()
          RETURN .F.
      ENDIF
  
      THISFORM.lempty = .F.
  
      THISFORM.onrecordmove()
  
      THISFORM.noldrecno = lnrecno
  
      THISFORM.coldtitle = THISFORM.CAPTION
  
      THISFORM.CAPTION = msg_insertmode + " " + ALLTRIM(THISFORM.CAPTION)
  
      THISFORM.refreshtoolbar(.T.)
  
      THISFORM.onformstatuschange()
  
      THISFORM.REFRESH()
  
      THISFORM.setobjectfocus()
  ELSE
      RETURN .F.
  ENDIF
  
  

• cdataform.onnext - Called when you move to the next record

  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnNext",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  SELECT (THISFORM.cworkalias)
  
  IF THISFORM.nformstatus <> id_normal_mode
      IF THISFORM.recordchanged() OR THISFORM.nformstatus = id_insert_mode
          IF !THISFORM.asktosave()
              ** Do Nothing
              RETURN .F.
          ENDIF
      ELSE
          THISFORM.onundo()
      ENDIF
  ENDIF
  
  THISFORM.orecord.NEXT()
  
  IF EOF()
      THISFORM.orecord.gobottom()
  ENDIF
  
  THISFORM.onrecordmove()
  
  THISFORM.REFRESH()
  
  

• cdataform.onpostinsert - Called by oninsert() after append blank. if return .f. insert is invalid and a tablerevert() it's used

  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnPostInsert",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  IF !EMPTY(THISFORM.cfixfieldname)
      LOCAL lcfield, lcfieldvalue, lnfield, j
  
      lnfield = getargcount(THISFORM.cfixfieldname)
  
      IF lnfield = 1
          lcfield      = THISFORM.cfixfieldname
          lcfieldvalue = THISFORM.cfixfieldvalue
  
          DO CASE
          CASE TYPE(lcfield) $ "NIBFY"
              REPLACE &lcfield WITH VAL(lcfieldvalue)
  
          CASE TYPE(lcfield) = "D"
              REPLACE &lcfield WITH CTOD(lcfieldvalue)
  
          CASE TYPE(lcfield) = "T"
              REPLACE &lcfield WITH CTOT(lcfieldvalue)
  
          CASE TYPE(lcfield) = "L"
              REPLACE &lcfield WITH (UPPER(lcfieldvalue) = "T")
  
          OTHERWISE
              REPLACE &lcfield WITH lcfieldvalue
          ENDCASE
      ELSE
          FOR j = 1 TO lnfield
              lcfield      = getarg(THISFORM.cfixfieldname ,j)
              lcfieldvalue = getarg(THISFORM.cfixfieldvalue,j)
  
              DO CASE
              CASE TYPE(lcfield) $ "NIBFY"
                  REPLACE &lcfield WITH VAL(lcfieldvalue)
  
              CASE TYPE(lcfield) = "D"
                  REPLACE &lcfield WITH CTOD(lcfieldvalue)
  
              CASE TYPE(lcfield) = "T"
                  REPLACE &lcfield WITH CTOT(lcfieldvalue)
  
              CASE TYPE(lcfield) = "L"
                  REPLACE &lcfield WITH (UPPER(lcfieldvalue) = "T")
  
              OTHERWISE
                  REPLACE &lcfield WITH lcfieldvalue
              ENDCASE
          NEXT
      ENDIF
  ENDIF
  
  

• cdataform.onprev - Called when moved to the previous record

  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnPrev",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  SELECT (THISFORM.cworkalias)
  
  IF THISFORM.nformstatus <> id_normal_mode
      IF THISFORM.recordchanged() OR THISFORM.nformstatus = id_insert_mode
          IF !THISFORM.asktosave()
              ** Do Nothing
              RETURN .F.
          ENDIF
      ELSE
          THISFORM.onundo()
      ENDIF
  ENDIF
  
  THISFORM.orecord.previous()
  
  IF BOF()
      THISFORM.orecord.gotop()
  ENDIF
  
  THISFORM.onrecordmove()
  
  THISFORM.REFRESH()
  
  

• cdataform.onprint - Called when print or preview has been called. Pass .t. as parameter for preview, otherwise print.

  PARAMETERS tlpreview
  LOCAL lcreportname, lnrecno, lnSelect, lcDefault
  lcDefault=SYS(5)+SYS(2003)
  
  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnPrint",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              SET DEFAULT TO (lcDefault)
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          SET DEFAULT TO (lcDefault)
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  *!* Store reord number from the workalias.
  lnrecno=RECNO(THIS.cworkalias)
  
  lcreportname = LOWER(ALLTRIM(THISFORM.creportname))
  
  IF EMPTY(lcreportname)
      lcreportname = STRTRAN(JUSTFNAME(LOWER(ALLTRIM(THISFORM.cscxname))),".scx",".frx")
  ENDIF
  
  IF RIGHT(lcreportname,4)#".frx"
      lcreportname = lcreportname+".frx"
  ENDIF
  
  IF !FILE(lcreportname) AND TYPE("goprogram.creportdir")="C"
      lcreportname = goprogram.creportdir+lcreportname
  ENDIF
  
  lnSelect=SELECT()
  
  IF FILE(lcreportname)
      IF tlpreview
          DEFINE WINDOW _preview FROM 0, 0 TO 10, 10;
              TITLE THIS.CAPTION+" ("+cap_preview+")" IN SCREEN CLOSE GROW SYSTEM FLOAT
          ZOOM WINDOW _preview MAX
          previewon()
          REPORT FORM (m.lcreportname) NOCONSOLE PREVIEW WINDOW _preview
          previewoff()
          RELEASE WINDOW _preview
      ELSE
          REPORT FORM (lcreportname) TO PRINTER NOCONSOLE
      ENDIF
  ELSE
      DO FORM vfxrepgn WITH THISFORM,THIS,tlpreview
  ENDIF
  
  IF m.lnrecno>0 AND m.lnRecno<=RECCOUNT(THIS.cworkalias)
      *!* Restore record pointer in workalias
      GOTO m.lnrecno IN (THIS.cworkalias)
  ENDIF
  
  * The report may have changed the alias. UH
  SELECT(m.lnSelect)
  SET DEFAULT TO (lcDefault)
  
  

• cdataform.onsave - Called when you save a record

  LPARAMETERS tlnotrefresh, tlalltables
  
  LOCAL laerror[7], lviewmessage, lsaved, lvalid, lcansave
  
  lsaved       = .F.
  lvalid       = .F.
  lcansave     = .T.
  
  lviewmessage = .T.
  
  *!* Write buffer value before the hook.
  THISFORM.onwritebuffer()
  
  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnSave",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  SELECT (THISFORM.cworkalias)
  
  IF DELETED()
  
      =MESSAGEBOX(msg_record_deleted_from_others,48,THISFORM.CAPTION)
      THISFORM.orecord.UNDO()
      THISFORM.orecord.gotop()
  
      THISFORM.onrecordmove()
  
      THIS.lcanedit = THIS.lactcanedit
  
      THISFORM.REFRESH()
  
      RETURN .F.
  ENDIF
  
  IF THISFORM.nformstatus = id_edit_mode
      lcansave  = THISFORM.onpostedit()
  ENDIF
  
  lvalid = THISFORM.VALID()
  
  IF lcansave AND lvalid
  
      SELECT (THISFORM.cworkalias)
  
      IF VARTYPE(goProgram)="O"
          IF !goprogram.lnoclearidxonedit
              goprogram.clearallidx()
          ENDIF
      ELSE
          THISFORM.clearidx()
      ENDIF
  
      lsaved = THISFORM.orecord.SAVE(tlalltables, THISFORM, @lvalid)
  ELSE
      lsaved = .F.
  ENDIF
  
  IF !lsaved
      IF lvalid
          lviewmessage = .T.
          laerror[1]   = 0
  
          =AERROR(laerror)
  
          IF laerror[1] != 0
              lviewmessage = !THISFORM.errorhandler(laerror[1])
          ENDIF
  
          IF lviewmessage AND lvalid
              =MESSAGEBOX(msg_not_saved,0+16,msg_attention)
          ENDIF
      ENDIF
  ELSE
      UNLOCK ALL
  
      THISFORM.CAPTION = THISFORM.coldtitle
  
      THISFORM.nformstatus = id_normal_mode
  
      THISFORM.lempty      = .F.
  
      SELECT (THISFORM.cworkalias)
  
      IF !EOF()
          GO RECNO()
      ELSE
          THISFORM.orecord.gotop()
      ENDIF
  
      THISFORM.noldrecno = IIF(EOF(THISFORM.cworkalias) OR DELETED(THISFORM.cworkalias), 0, RECNO(THISFORM.cworkalias))
  
      THISFORM.refreshtoolbar(.T.)
  
      THISFORM.onformstatuschange()
  
      THIS.onpostsave()
  
      IF !tlnotrefresh
          THISFORM.REFRESH()
      ENDIF
  
      IF VARTYPE(goProgram)="O" AND goprogram.lremakeidxafterclear
          THISFORM.remakeidx("S")
      ENDIF
  
      IF TYPE("thisForm.oPickField")="O" AND !ISNULL(THISFORM.opickfield)
  
          ** Pick the selected value
  
          LOCAL lcretval, lopickfield
  
          lopickfield = THISFORM.opickfield
  
          IF TYPE("loPickField._VFXClassName")="C" AND ;
                  lopickfield._vfxclassname == "CLookUp"
  
              lopickfield.lupdated = .T.
  
              lopickfield.VALID(EVAL(lopickfield.csearchexpr))
  
              lopickfield.writebuffer()
  
              THISFORM.RELEASE()
              RETURN lsaved
          ENDIF
  
          lcretval = EVALUATE(lopickfield.creturnexpr) + ";"
  
          LOCAL luvalue
  
          IF UPPER(lopickfield.BASECLASS) = "CONTAINER"
              IF EMPTY(lopickfield.creturnexprdesc)
                  lcretval = lcretval +  ";"
              ELSE
                  luvalue  = EVALUATE(lopickfield.creturnexprdesc)
                  lcretval = lcretval + IIF(EMPTY(NVL(luvalue,"")), ";", luvalue + ";")
              ENDIF
          ELSE
              lcretval = lcretval +  ";"
          ENDIF
  
          IF EMPTY(lopickfield.creturnmoreexpr)
              lcretval = lcretval
          ELSE
              luvalue  = EVALUATE(lopickfield.creturnmoreexpr)
              lcretval = lcretval + IIF(!EMPTY(NVL(luvalue,"")), luvalue, "")
          ENDIF
  
          IF !EMPTY(lcretval)
              LOCAL lorec
              SCATTER MEMO NAME lorec
              lopickfield.opickrec = lorec
              RELEASE lorec
  
              lopickfield.setvalues(lcretval)
  
          ENDIF
  
          THISFORM.RELEASE()
      ENDIF
  
  ENDIF
  
  THIS.lcanedit = THIS.lactcanedit
  
  RETURN lsaved
  
  

• cdataform.onsearch - Called when you user selects the search button

  LPARAMETERS tofieldlist
  
  LOCAL lcfilterexpr, lnoldrec
  
  SELECT (THISFORM.cworkalias)
  
  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnSearch",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  IF EMPTY(THISFORM.csearchform)
      RETURN .F.
  ENDIF
  
  IF THISFORM.nformstatus <> id_normal_mode
      IF THISFORM.recordchanged() OR THISFORM.nformstatus = id_insert_mode
          IF !THISFORM.asktosave()
              ** Do Nothing
              RETURN .F.
          ENDIF
      ELSE
          THISFORM.nformstatus = id_normal_mode
          THISFORM.CAPTION = THISFORM.coldtitle
          THISFORM.refreshtoolbar(.T.)
          THISFORM.onformstatuschange()
          THISFORM.REFRESH()
      ENDIF
  ENDIF
  
  * Enhancement to use fields used in grid.
  * goProgram.nOnSearchUseGrid=0 use form setting
  * goProgram.nOnSearchUseGrid=1 use grid in all forms
  * goProgram.nOnSearchUseGrid=2 use fields in all forms
  IF TYPE("toFieldlist")#"O"
      IF TYPE("goProgram.nOnSearchUseGrid")="N"
          IF goprogram.nonsearchusegrid>0
              THISFORM.lonsearchusegrid=(goprogram.nonsearchusegrid=1)
          ENDIF
      ENDIF
      IF THISFORM.lonsearchusegrid
          LOCAL lnz,lcz
          DO CASE
  
          CASE UPPER(THIS._vfxclassname)="CDATAFORMPAGE" OR UPPER(THIS._vfxclassname)="CONETOMANY"
              IF THIS.npagelist>0
                  *!* Delayed instatiation: grid may not be instantiated...
                  IF TYPE("this.pgfPageFrame.pages(this.nPageList).grdGrid")#"O"
                      THIS.pgfpageframe.PAGES(THIS.npagelist).ACTIVATE()
                  ENDIF
                  tofieldlist=CREATEOBJECT("cFieldlist")
                  tofieldlist.ctablelist=""
                  WITH THIS.pgfpageframe.PAGES(THIS.npagelist).grdgrid
                      FOR lnz=1 TO .COLUMNCOUNT
                          tofieldlist.addcontrolsource(.COLUMNS(lnz).CONTROLSOURCE,.COLUMNS(lnz).header1.CAPTION)
                      NEXT
                  ENDWITH
              ENDIF
  
          *!* Use _vfxclassname
          CASE UPPER(THIS._vfxclassname)="CTABLEFORM"
              tofieldlist=CREATEOBJECT("cfieldlist")
              tofieldlist.ctablelist=""
              WITH THIS.cntpanel.grdgrid
                  FOR lnz=1 TO .COLUMNCOUNT
                      lcz=TRANSFORM(m.lnz)
                      tofieldlist.addcontrolsource(.COLUMN&lcz..CONTROLSOURCE,.COLUMN&lcz..header1.CAPTION)
                  NEXT
              ENDWITH
          ENDCASE
      ENDIF
  ENDIF
  
  
  lcfilterexpr = THISFORM.csearchfilterexpr
  
  lnoldrec = IIF(EOF() OR DELETE() ,0,RECNO())
  
  DO FORM (THISFORM.csearchform) WITH tofieldlist TO THISFORM.csearchfilterexpr
  
  SELECT (THISFORM.cworkalias)
  
  IF TYPE("thisForm.cSearchFilterExpr") # "C"
      RETURN .T.
  ENDIF
  
  IF !EMPTY(THISFORM.csearchfilterexpr)
      IF !EMPTY(THISFORM.cfilterexpr)
          lcfilterexpr = THISFORM.cfilterexpr + " AND " + THISFORM.csearchfilterexpr
      ELSE
          lcfilterexpr = THISFORM.csearchfilterexpr
      ENDIF
  
      LOCAL lcerror,lerror
      lcerror = ON('ERROR')
      ON ERROR lerror=.T.
      SET FILTER TO &lcfilterexpr
      ON ERROR &lcerror
  
      THISFORM.orecord.gotop()
  
      *!* Check for errors in the filter condition
      IF EOF() OR DELETE() OR lerror
          = MESSAGEBOX(msg_no_record_found,mb_iconinformation,msg_attention)
  
          THISFORM.csearchfilterexpr = ""
  
          IF !EMPTY(THISFORM.cfilterexpr)
              lcfilterexpr = UPPER(THISFORM.cfilterexpr)
          ELSE
              lcfilterexpr = THISFORM.csearchfilterexpr
          ENDIF
  
          SET FILTER TO &lcfilterexpr
  
          IF lnoldrec # 0
              GO lnoldrec
          ELSE
              THISFORM.orecord.gotop()
          ENDIF
      ENDIF
  ELSE
      IF !EMPTY(THISFORM.cfilterexpr)
          lcfilterexpr = UPPER(THISFORM.cfilterexpr)
      ELSE
          lcfilterexpr = ''
      ENDIF
  
      SET FILTER TO &lcfilterexpr
  
      IF lnoldrec # 0
          GO lnoldrec
      ELSE
          THISFORM.orecord.gotop()
      ENDIF
  ENDIF
  
  IF EMPTY(THISFORM.csearchfilterexpr)
      THISFORM.CAPTION = STRTRAN(THISFORM.CAPTION, " ["+msg_filter_on+"]", "")
      THISFORM.lfilteron = .F.
  ELSE
      LOCAL lctext
  
      lctext = STRTRAN(THISFORM.CAPTION, " ["+msg_filter_on+"]", "")
  
      THISFORM.CAPTION = lctext + " ["+msg_filter_on+"]"
      THISFORM.lfilteron = .T.
  ENDIF
  
  THISFORM.refreshtoolbar(.T.)
  THISFORM.REFRESH()
  
  

• cdataform.ontop - Called when user selects go top

  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnTop",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  SELECT (THISFORM.cworkalias)
  
  IF THISFORM.nformstatus <> id_normal_mode
      IF THISFORM.recordchanged() OR THISFORM.nformstatus = id_insert_mode
          IF !THISFORM.asktosave()
              ** Do Nothing
              RETURN .F.
          ENDIF
      ELSE
          THISFORM.onundo()
      ENDIF
  ENDIF
  
  THISFORM.orecord.gotop()
  
  THISFORM.onrecordmove()
  
  THISFORM.REFRESH()
  
  

• cdataform.onundo - Called when user selects undo

  LPARAMETERS tlnotrefresh
  
  IF TYPE("thisform.activecontrol") = "O" AND pemstatus(THISFORM.ACTIVECONTROL,'lnorefresh',5)
      THISFORM.ACTIVECONTROL.lnorefresh = .F.
  ENDIF
  
  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnUndo",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  SELECT (THISFORM.cworkalias)
  
  IF VARTYPE(goProgram)="O"
      IF !goprogram.lnoclearidxonedit
          goprogram.clearallidx()
      ENDIF
  ELSE
      THISFORM.clearidx()
  ENDIF
  
  THISFORM.orecord.UNDO()
  
  THISFORM.CAPTION = THISFORM.coldtitle
  
  THISFORM.nformstatus = id_normal_mode
  
  IF THISFORM.noldrecno > 0 AND THISFORM.noldrecno<=RECCOUNT()
      GO THISFORM.noldrecno
  ELSE
      THISFORM.orecord.gotop()
  ENDIF
  
  THISFORM.onrecordmove()
  
  THISFORM.onformstatuschange()
  
  THISFORM.refreshtoolbar(.T.)
  
  THIS.lcanedit = THIS.lactcanedit
  
  IF !tlnotrefresh
      THISFORM.REFRESH()
  ENDIF
  
  UNLOCK ALL
  
  IF VARTYPE(goProgram)="O" AND goprogram.lremakeidxafterclear
      THISFORM.remakeidx("U")
  ENDIF
  
  

• cdataform.onwritebuffer - Save current active control value into data buffer. NOTE: VFP does NOT do this automatically, this is by design. You might already know: It's a feature not a bug

  LOCAL llretval
  
  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnWriteBuffer",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  SELECT (THISFORM.cworkalias)
  
  IF TYPE("thisForm.ActiveControl")="O"
      LOCAL locontrol
  
      locontrol = THISFORM.ACTIVECONTROL
  
      IF LOWER(locontrol.BASECLASS) == "grid"
          LOCAL lncolumn, logrid, j, lccontrolname
  
          logrid = locontrol
  
          IF logrid.ACTIVECOLUMN > 0
              lccontrolname = logrid.COLUMNS[loGrid.ActiveColumn].CURRENTCONTROL
  
              locontrol = logrid.COLUMNS[loGrid.ActiveColumn].&lccontrolname.
  
              IF pemstatus(locontrol,'ControlSource',5)
                  IF !EMPTY(locontrol.COMMENT) AND locontrol.COMMENT<>"*"
                      IF pemstatus(locontrol,'LostFocus',5)
                          locontrol.LOSTFOCUS()
                      ENDIF
  
                      IF pemstatus(locontrol,'SetFocus',5)
                          locontrol.SETFOCUS()
                      ENDIF
                  ENDIF
              ENDIF
          ENDIF
      ELSE
          IF pemstatus(locontrol,'LostFocus',5)
              locontrol.LOSTFOCUS()
          ENDIF
  
          IF pemstatus(locontrol,'SetFocus',5)
              locontrol.SETFOCUS()
          ENDIF
      ENDIF
  ENDIF
  
  RETURN .T.
  
  

• cdataform.recordchanged - Returns .t. if current record has been changed

  RETURN THISFORM.orecord.modified()
  
  

• cdataform.recorderror - Called by the form's errorhandler when record trigger is violated

  LOCAL laerror[7],lcalias,lcmessage
  lcmessage=""
  =AERROR(laerror)
  IF laerror[1]=1583
      =MESSAGEBOX(laerror[2],mb_ok+mb_iconstop,msg_attention)
  ELSE
      lcalias = ALIAS(laerror[4])
      IF !ISNULL(lcalias) AND !EMPTY(lcalias)
          DO CASE
          CASE CURSORGETPROP("SOURCETYPE") <> 2
              lcmessage = DBGETPROP(lcalias, "TABLE", "RULETEXT")
  
          OTHERWISE
              lcmessage = laerror[2]
          ENDCASE
      ENDIF
      IF !EMPTY(lcmessage)
          =MESSAGEBOX(lcmessage,mb_ok+mb_iconstop,msg_attention)
      ENDIF
  ENDIF
  

• cdataform.requery - This is the main method to requery any kind of data. Especially in C/S development very important method.

  LPARAMETER tlloaddata, tlrefreshonly
  
  SELECT (THISFORM.cworkalias)
  
  IF EMPTY(THISFORM.cworkalias)
      THISFORM.lempty    = .T.
      THISFORM.noldrecno = 0
      RETURN .F.
  ENDIF
  
  IF !THISFORM.lempty
      IF THISFORM.lworkonview
          IF !";" $ THISFORM.cfixfieldname AND ;
                  !EMPTY(THISFORM.cfixfieldname) AND converttochar(EVAL(THISFORM.cfixfieldname)) == THISFORM.cfixfieldvalue
              RETURN .F.
          ENDIF
      ELSE
          IF THISFORM.lusesetkeyasfilter
              IF UPPER(converttochar(SET("key",1))) == UPPER(converttochar(THISFORM.csetkeyvalue))
                  RETURN .F.
              ENDIF
          ELSE
              IF FILTER() == UPPER(STRTRAN(STRTRAN(STRTRAN(THISFORM.cfilterexpr, " ", ""), "[", '"'), "]", '"'))
                  RETURN .F.
              ENDIF
          ENDIF
      ENDIF
  ENDIF
  
  LOCAL lcindexname, lcindexexpr,lcparameters, lnsymbolcount
  
  IF !THISFORM.onprequery()
      THISFORM.orecord.gotop()
  
      THISFORM.onrecordmove()
  
      RETURN .F.
  ENDIF
  
  SELECT (THISFORM.cworkalias)
  
  LOCAL luserfields
  
  luserfields = !THISFORM.setqueryarg()
  
  IF THISFORM.lworkonview
      lnsymbolcount = 0
  
      WAIT WINDOW msg_working NOWAIT
  
      IF tlrefreshonly
          = REQUERY()
      ELSE
          IF  tlloaddata
  
              lcparameters = ''
  
              IF !luserfields
                  lcparameters = ALLTRIM(DBGETPROP(CURSORGETPROP("sourcename",THISFORM.cworkalias),'view','SQL'))
              ENDIF
  
              IF !EMPTY(lcparameters)
                  LOCAL lnargcount, lcsymbol, lcvalue, lasymtable[1], lnsymcount, lctext, k
  
                  lnargcount = OCCURS('?',lcparameters)
                  lnsymbolcount = 0
  
                  FOR j = 1 TO lnargcount
                      lctext = ''
  
                      lcsymbol = SUBSTR(lcparameters,AT('?',lcparameters,j)+1)
  
                      lctext = ''
  
                      FOR k = 1 TO LEN(lcsymbol)
                          IF LOWER(SUBSTR(lcsymbol,k,1)) $ "abcdefghijklmnopqrstuvwxyz0123456789_"
                              lctext = lctext + SUBSTR(lcsymbol,k,1)
                          ELSE
                              EXIT
                          ENDIF
                      NEXT
  
                      IF !EMPTY(lctext)
                          lcsymbol = lctext
  
                          lnsymbolcount = lnsymbolcount + 1
  
                          DIMENSION lasymtable[lnSymbolCount]
  
                          lasymtable[lnSymbolCount] = lcsymbol
  
                          IF TYPE(lcsymbol) = "U"
                              PUBLIC (lcsymbol)
                          ENDIF
  
                          IF EMPTY(THISFORM.cfixfieldname)
                              &lcsymbol = getarg(THISFORM.cqueryarg,j)
                          ELSE
                              LOCAL lcfield
  
                              lcfield  = getarg(THISFORM.cfixfieldname ,j)
  
                              DO CASE
                              CASE TYPE(lcfield) $ "NIBFY"
                                  &lcsymbol = VAL(getarg(THISFORM.cqueryarg,j))
  
                              CASE TYPE(lcfield) = "D"
                                  &lcsymbol = CTOD(getarg(THISFORM.cqueryarg,j))
  
                              CASE TYPE(lcfield) = "T"
                                  &lcsymbol = CTOT(getarg(THISFORM.cqueryarg,j))
  
                              CASE TYPE(lcfield) = "L"
                                  &lcsymbol = (UPPER(getarg(THISFORM.cqueryarg,j)) = "T")
  
                              OTHERWISE
                                  &lcsymbol = getarg(THISFORM.cqueryarg,j)
  
                              ENDCASE
                          ENDIF
                          *}
                      ENDIF
                  NEXT
  
                  =REQUERY()
  
                  FOR j = 1 TO lnsymbolcount
                      lcsymbol = lasymtable[j]
                      RELEASE (lcsymbol)
                  NEXT
              ELSE
                  = REQUERY()
              ENDIF
          ENDIF
      ENDIF
  
      IF !EMPTY(THISFORM.cviewindexexpr)
          lcindexname = "X"+SUBSTR(SYS(2015),4,7)
          lcindexexpr = THISFORM.cviewindexexpr
  
          INDEX ON &lcindexexpr TAG (lcindexname) ADDITIVE
      ENDIF
  
      IF !EMPTY(THISFORM.cfilterexpr) AND !THISFORM.lusesetkeyasfilter
          LOCAL lcfilterexpr
  
          lcfilterexpr = THISFORM.cfilterexpr
  
          SET FILTER TO &lcfilterexpr
      ENDIF
  
      WAIT CLEAR
  ELSE
      * Working on standard Tables
      IF THISFORM.lusesetkeyasfilter
          LOCAL lckeyvalue
  
          THISFORM.cworktag = THISFORM.csetkeyindex
  
          SELECT (THISFORM.cworkalias)
          SET ORDER TO TAG(THISFORM.cworktag)
  
          lckeyvalue = converttochar(THISFORM.csetkeyvalue)
  
          DO CASE
          CASE TYPE(THISFORM.csetkeyexpr) $"NIBFY"
              SET KEY TO VAL(lckeyvalue)
              THISFORM.csetkeyvalue = VAL(lckeyvalue)
  
          CASE TYPE(THISFORM.csetkeyexpr) $ "DT"
              SET KEY TO DTOS(CTOD(lckeyvalue))
              THISFORM.csetkeyvalue = DTOS(CTOD(lckeyvalue))
  
          OTHERWISE
              ** Default it's Character
              IF "UPPER(" $ THISFORM.csetkeyexpr
                  SET KEY TO UPPER(lckeyvalue)
                  THISFORM.csetkeyvalue = UPPER(lckeyvalue)
              ELSE
                  SET KEY TO lckeyvalue
                  THISFORM.csetkeyvalue = lckeyvalue
              ENDIF
          ENDCASE
      ENDIF
  
      IF !EMPTY(THISFORM.cfilterexpr) AND !THISFORM.lusesetkeyasfilter
          LOCAL lcfilterexpr
  
          lcfilterexpr = THISFORM.cfilterexpr
  
          SET FILTER TO &lcfilterexpr
      ENDIF
  ENDIF
  
  THISFORM.clearqueryarg()
  
  THISFORM.orecord.gotop()
  
  THISFORM.onrecordmove()
  
  THISFORM.onpostquery()
  
  RETURN .T.
  
  

• cdataform.triggererror - Called by the form's errorhandler when table trigger is violated

  LOCAL laerror[7], lcmsg
  
  =AERROR(laerror)
  
  DO CASE
  CASE laerror[5] = 1
      lcmsg = "Insert Record"
  CASE laerror[5] = 2
      lcmsg = "Update Record"
  CASE laerror[5] = 3
      lcmsg = "Delete Record"
  ENDCASE
  
  =MESSAGEBOX(laerror[2],64,lcmsg)
  
  

• cdataform.uniqueerror - Called by the forms errorhandler when unique key is violated

  LPARAMETER tlskipmessage
  LOCAL laerror[7]
  
  =AERROR(laerror)
  
  IF !tlskipmessage
      =MESSAGEBOX(msg_keyfield_error,;
          mb_ok+48,msg_attention)
  ENDIF
  
  

• cdataform.updateerror - Called by the form's errorhandler when update trigger is violated

  LOCAL laerror[7], lcmsg
  
  =AERROR(laerror)
  
  lcmsg = "Update Error: " + ALIAS()
  
  =MESSAGEBOX(laerror[2],64,lcmsg)
  
  

• cdataform.setkeyreset - Resets the SET KEY expression

  LPARAMETERS tlreload
  
  IF THISFORM.lusesetkeyasfilter
      LOCAL lckeyvalue
  
      IF !("VFXFUNC" $ SET('proc'))
          SET PROCEDURE TO PROGRAM\vfxfunc ADDITIVE
      ENDIF
  
      lckeyvalue = converttochar(THISFORM.csetkeyvalue)
  
      DO CASE
  
      CASE TYPE(THISFORM.csetkeyexpr) $ "NIBFY"
          SET KEY TO VAL(lckeyvalue)
  
      CASE TYPE(THISFORM.csetkeyexpr) $ "DT"
          SET KEY TO DTOS(CTOD(lckeyvalue))
  
      OTHERWISE
          ** Default it's Character
          IF "UPPER(" $ THISFORM.csetkeyexpr
              SET KEY TO UPPER(lckeyvalue)
          ELSE
              SET KEY TO lckeyvalue
          ENDIF
      ENDCASE
  
      IF tlreload
          THISFORM.orecord.gotop()
      ENDIF
  ENDIF
  
  

• cdataform.onrecordmove - Called each time the record pointer is moved.

  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnRecordMove",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  THISFORM.lempty = EOF(THISFORM.cworkalias) OR DELETED(THISFORM.cworkalias)
  
  THISFORM.noldrecno = IIF(EOF(THISFORM.cworkalias) OR DELETED(THISFORM.cworkalias), 0, RECNO(THISFORM.cworkalias))
  
  IF THISFORM.lworkonview
      THISFORM.onchildrequery()
  ENDIF
  
  IF THISFORM.lautosyncchildform
      THISFORM.oformlist.refreshallchild()
  ENDIF
  
  THISFORM.onemptyform()
  
  

• cdataform.setqueryarg - If you write a custom code to set the query this function must return .F.. Please refer also to the requery method to track this functionality.

  IF THISFORM.lworkonview
      THISFORM.cqueryarg = THISFORM.cfixfieldvalue
  ENDIF
  
  

• cdataform.onemptyform - Called from various methods whenever no records may exist in the current form

  IF THISFORM.lhidewhenempty
      WITH THISFORM.lblmsgempty
  
          .CAPTION = THISFORM.cemptymessage
  
          .TOP     = (THISFORM.HEIGHT - .HEIGHT)/2
          .LEFT    = (THISFORM.WIDTH  - .WIDTH )/2
  
          IF .VISIBLE#THISFORM.lempty
              .VISIBLE = THISFORM.lempty
              THISFORM.REFRESH
          ENDIF
      ENDWITH
  ENDIF
  
  

• cdataform.asktosave - Question whether data will have to be saved or not.

  LPARAMETERS tlyesno
  
  IF THIS.WINDOWSTATE=1
      THIS.WINDOWSTATE=0
  ENDIF
  
  IF THISFORM.lasktosave
      LOCAL lnanswer
  
      IF tlyesno
          lnanswer = MESSAGEBOX(msg_ask_to_save,;
              4+mb_iconexclamation+mb_defbutton1,;
              msg_attention)
      ELSE
          lnanswer = MESSAGEBOX(msg_ask_to_save,;
              mb_yesnocancel+mb_iconexclamation+mb_defbutton1,;
              msg_attention)
      ENDIF
  
      DO CASE
      CASE lnanswer = idyes
          IF !THISFORM.onsave()
              RETURN .F.    && Don't move
          ENDIF
  
      CASE lnanswer = idno
          THISFORM.onundo()
  
      OTHERWISE
          RETURN .F.        && Don't move
      ENDCASE
  ELSE
      IF !THISFORM.onsave()
          RETURN .F.            && Don't move
      ENDIF
  ENDIF
  
  RETURN .T.    && Ok, you can move
  
  

• cdataform.onaudit - Calls the audit trail for the current record.

  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnAudit",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  * Show the form with the Audit-Trail for the current record.
  LOCAL lnpknum,lnid,lnselect,lctext
  lnselect=SELECT(0)
  lnpknum=getpknum()
  IF lnpknum <> 0
      lnid = EVAL(KEY(lnpknum))
      lctext=getaudit(THISFORM.cworkalias, lnid)
      IF EMPTY(lctext)
          MESSAGEBOX(msg_noaudit,16,msg_audit)
      ELSE
          DO FORM vfxaudit WITH cap_frmaudittrail+" "+THISFORM.CAPTION, lctext
      ENDIF
  ENDIF
  SELECT(lnselect)
  
  

• cdataform.viafavorite - Method when form get's called through the favorites dialog.

  LPARAMETERS txid
  
  SELECT (THISFORM.cworkalias)
  IF THISFORM.nformstatus <> id_normal_mode
      IF THISFORM.recordchanged() OR THISFORM.nformstatus = id_insert_mode
          IF !THISFORM.asktosave()
              ** Do Nothing
              RETURN .F.
          ENDIF
      ELSE
          THISFORM.onundo()
      ENDIF
  ENDIF
  
  LOCAL lnselect,lnpknum,lckey,lcfieldname
  lnselect = SELECT(0)
  SELECT (THIS.cworkalias)
  IF EMPTY(THIS.cfavoriteid)
      lnpknum    = getpknum()
      IF lnpknum    = 0
          SELECT(lnselect)
          RETURN .F.
      ENDIF
      lckey=KEY(lnpknum)
      lcfieldname=lckey
      lcfieldname=STRTRAN(lcfieldname,"UPPER(","")
      lcfieldname=STRTRAN(lcfieldname,"LOWER(","")
      lcfieldname=STRTRAN(lcfieldname,"STR(","")
      lcfieldname=STRTRAN(lcfieldname,")","")
      IF TYPE(ALLTRIM(THIS.cworkalias)+"."+lcfieldname)="C"
          LOCATE FOR &lckey. = txid
      ELSE
          LOCATE FOR &lckey. = VAL(txid)
      ENDIF
  ELSE
      lckey=THIS.cfavoriteid
      IF TYPE(lckey)="C"
          LOCATE FOR &lckey. = txid
      ELSE
          LOCATE FOR &lckey. = VAL(txid)
      ENDIF
  ENDIF
  SELECT(lnselect)
  THIS.REFRESH()
  THIS.onrecordmove()
  IF thisform.windowstate = 1
      thisform.windowstate = 0
  ENDIF
  RETURN FOUND()
  
  

• cdataform.oncopy - Called when you copy a record.

  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnCopy",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  IF !THISFORM.lcancopy
      WAIT WINDOW msg_cant_insert
      RETURN .F.
  ENDIF
  
  IF THISFORM.nformstatus <> id_normal_mode
      IF !THISFORM.asktosave()
          ** Do Nothing
          RETURN .F.
      ENDIF
  
      THISFORM.nformstatus = id_normal_mode
      THISFORM.CAPTION = THISFORM.coldtitle
      THISFORM.refreshtoolbar(.T.)
      THISFORM.onformstatuschange()
      THISFORM.REFRESH()
  ENDIF
  
  THIS.lactcanedit = THIS.lcanedit
  THIS.lcanedit = .T.
  
  LOCAL lnrecno,lofields
  
  SELECT (THISFORM.cworkalias)
  
  lnrecno = IIF(EOF() OR DELETED(), 0, RECNO())
  
  THISFORM.noldrecno = lnrecno
  
  SCATTER MEMO NAME lofields
  THIS.ofields = lofields
  
  IF THISFORM.onprecopy()
      SELECT (THISFORM.cworkalias)
  
      IF VARTYPE(goProgram)="O"
          IF !goprogram.lnoclearidxoninsert
              goprogram.clearallidx()
          ENDIF
      ELSE
          THISFORM.clearidx()
      ENDIF
  
      SELECT (THISFORM.cworkalias)
  
      THISFORM.orecord.INSERT()
  
      ** Check the Active control
      IF TYPE("thisForm.ActiveControl")="O"
          LOCAL locontrol
  
          locontrol = THISFORM.ACTIVECONTROL
  
          IF LOWER(locontrol.BASECLASS) == "grid"
              locontrol.REFRESH()
          ENDIF
      ENDIF
  
      IF !THISFORM.onpostcopy()
          THISFORM.onundo()
          RETURN .F.
      ENDIF
  
      IF THISFORM.nformstatus != 0 AND !EMPTY(THISFORM.coldtitle)
          THISFORM.CAPTION = THISFORM.coldtitle
      ENDIF
  
      THISFORM.nformstatus = id_insert_mode
  
      THISFORM.lempty = .F.
  
      THISFORM.onrecordmove()
  
      THISFORM.noldrecno = lnrecno
  
      THISFORM.coldtitle = THISFORM.CAPTION
  
      THISFORM.CAPTION = msg_insertmode + " " + ALLTRIM(THISFORM.CAPTION)
  
      THISFORM.refreshtoolbar(.T.)
  
      THISFORM.onformstatuschange()
  
      THISFORM.REFRESH()
  
      THISFORM.setobjectfocus()
  ELSE
      RETURN .F.
  ENDIF
  
  

• cdataform.onpostcopy - Called by oncopy() after append and gather. if return .f. copy is invalid and a tablerevert() it's used

  LOCAL lofields,lnkey,lcfieldname
  lofields = THIS.ofields
  * dont replace primary
  lnkey=getpknum()
  IF lnkey>0
      lcfieldname=KEY(lnkey)
      lcfieldname=STRTRAN(lcfieldname,"UPPER(","")
      lcfieldname=STRTRAN(lcfieldname,"LOWER(","")
      lcfieldname=STRTRAN(lcfieldname,"STR(","")
      lcfieldname=STRTRAN(lcfieldname,")","")
      lcproperty="loFields."+lcfieldname
      IF TYPE(lcproperty)#"U"
          lofields.&lcfieldname. = EVAL(KEY(lnkey))
      ENDIF
  ENDIF
  * dont replace candidates
  lnkey=getcknum(1)
  DO WHILE lnkey>0
      lcfieldname=KEY(lnkey)
      lcfieldname=STRTRAN(lcfieldname,"UPPER(","")
      lcfieldname=STRTRAN(lcfieldname,"LOWER(","")
      lcfieldname=STRTRAN(lcfieldname,"STR(","")
      lcfieldname=STRTRAN(lcfieldname,")","")
      lcproperty="loFields."+lcfieldname
      IF TYPE(lcproperty)#"U"
          lofields.&lcfieldname. = EVAL(KEY(lnkey))
      ENDIF
      lnkey=getcknum(lnkey+1)
  ENDDO
  
  * don´t replace insert & update info
  lcfieldname="ins_date"
  lcproperty="loFields."+lcfieldname
  IF TYPE(lcproperty)#"U"
      lofields.&lcfieldname. = EVAL(lcfieldname)
  ENDIF
  lcfieldname="ins_usr"
  lcproperty="loFields."+lcfieldname
  IF TYPE(lcproperty)#"U"
      lofields.&lcfieldname. = EVAL(lcfieldname)
  ENDIF
  lcfieldname="edt_date"
  lcproperty="loFields."+lcfieldname
  IF TYPE(lcproperty)#"U"
      lofields.&lcfieldname. = EVAL(lcfieldname)
  ENDIF
  lcfieldname="edt_usr"
  lcproperty="loFields."+lcfieldname
  IF TYPE(lcproperty)#"U"
      lofields.&lcfieldname. = EVAL(lcfieldname)
  ENDIF
  
  GATHER NAME lofields MEMO
  
  * make sure the onpostinsert get's called i.e. for PK assignments using numerators
  IF !THISFORM.onpostinsert()
      THISFORM.onundo()
      RETURN .F.
  ENDIF
  
  RETURN .T.
  
  

• cdataform.jumpto - Method to jump to a specific record from externally. Pass two parameters tcfieldexpr and tuvalue. These two parameters are used like this: LOCATE FOR UPPER(LTRIM(&tcfieldexpr)) = UPPER(LTRIM(tuvalue)) to position on the desired record.

  LPARAMETERS tcfieldexpr, tuvalue
  
  LOCAL lcexprtype
  lcexprtype = TYPE(tcfieldexpr)
  
  IF !EMPTY(tuvalue)
      LOCAL lctype
      lctype = TYPE("tuValue")
  
      DO CASE
          * character expressions
      CASE lcexprtype = "C"
          DO CASE
          CASE lctype = "C"
              * do nothing
          CASE lctype  $ "NIFBY"
              tuvalue = STR(tuvalue,100)
          ENDCASE
  
          * numeric expressions
      CASE lcexprtype $ "NIFBY"
          DO CASE
          CASE lctype = "C"
              tuvalue = VAL(ALLTRIM(tuvalue))
          CASE lctype = "N"
              * do nothing
          ENDCASE
      ENDCASE
  
      IF lcexprtype = TYPE("tuValue") AND lcexprtype = "C"
          LOCATE FOR UPPER(LTRIM(&tcfieldexpr)) = UPPER(LTRIM(tuvalue))
      ELSE
          LOCATE FOR &tcfieldexpr = tuvalue
      ENDIF
  
      IF !FOUND()
          IF lcexprtype = TYPE("tuValue")
              LOCAL lnlen, lclocateexpr, lcvalue, lcorigvalue
              lnlen        = 0
              lclocateexpr = ""
              lcvalue      = ""
              lcorigvalue  = ""
  
              lclocateexpr = "alltrim("+tcfieldexpr+")"
  
              DO CASE
              CASE TYPE("tuValue") = "C"
                  lnlen       = LEN(ALLTRIM(tuvalue)) - 1
                  lcorigvalue = ALLTRIM(tuvalue)
              CASE TYPE("tuValue") = "N"
                  lnlen       = LEN(TRANSFORM(tuvalue)) - 1
                  lcorigvalue = TRANSFORM(tuvalue)
                  lclocateexpr = "alltrim("+tcfieldexpr+")"
              OTHERWISE
              ENDCASE
  
              IF lnlen > 0
                  lcvalue = lcorigvalue
                  DO WHILE lnlen > 0
                      lcvalue = SUBSTR(lcvalue, 1, lnlen)
                      LOCATE FOR &lclocateexpr = lcvalue
  
                      lnlen = lnlen - 1
                      IF  FOUND()
                          EXIT
                      ENDIF
                  ENDDO
              ENDIF
  
              IF !FOUND() OR lnlen < 0
                  LOCATE
              ENDIF
          ELSE
              LOCATE
          ENDIF
      ENDIF
  ENDIF
  
  

• cdataform.caption_assign

  LPARAMETERS vnewval
  LOCAL lccallingprogram
  lccallingprogram=PROGRAM(PROGRAM(-1)-1)
  IF TYPE("lcCallingProgram")="C"
      IF LOWER(RIGHT(lccallingprogram,15))=".onsetchilddata"
          THIS.coldtitle=m.vnewval
      ENDIF
  ENDIF
  THIS.CAPTION = m.vnewval
  
  

• cdataform.remakeidx - Can be used to recreate temporary index files when they have been deleted due tu a delete, undo or save operation. See also cfoxapp.lremakeidxafterclear

  LPARAMETERS tcmodus
  
  LOCAL lcalias
  lcalias = ALIAS()
  
  LOCAL j, k, loobject, lllocate
  j = 0
  k = 0
  loobject = .NULL.
  lllocate = .F.
  
  DO CASE
  CASE TYPE("this.cntPanel.grdGrid") = "O"
      loobject = THIS.cntpanel.grdgrid
      lllocate = .T.
      THIS.remakegrididx(loobject, lllocate, tcmodus)
  
  CASE TYPE("this.pgfpageframe") = "O"
      WITH THIS.pgfpageframe
          FOR j = 1 TO .PAGECOUNT
              FOR k = 1 TO .PAGES[j].CONTROLCOUNT
                  IF LOWER(.PAGES[j].CONTROLS[k].BASECLASS) = 'grid'  AND  ;
                          !EMPTY(NVL(LOWER(.PAGES[j].CONTROLS[k].PARENTCLASS),""))
                      loobject = .PAGES[j].CONTROLS[k]
                      lllocate = (THIS.npagelist = j)
  
                      THIS.remakegrididx(loobject, lllocate, tcmodus)
                  ENDIF
              NEXT
          NEXT
      ENDWITH
  
  ENDCASE
  
  IF !EMPTY(lcalias)  AND  USED(lcalias)
      SELECT (lcalias)
  ENDIF
  
  RETURN
  
  

• cdataform.remakegrididx - Called from the remakeidx method

  LPARAMETERS togrid, tllocate, tcmodus
  
  LOCAL logrid, lccolumnn, lcsortcolumns, lcsortexpr, lcsortexprval, i, lllocate
  logrid        = togrid
  
  i             = 0
  lccolumn      = ""
  lcsortcolumns = ""
  lcsortexpr    = ""
  lcsortexprval = ""
  lllocate      = tllocate
  
  IF TYPE("loGrid") <> "O"
      RETURN .F.
  ELSE
      IF pemstatus(logrid, "baseclass", 5)
          IF LOWER(logrid.BASECLASS) <> 'grid'
              RETURN .F.
          ENDIF
      ELSE
          RETURN .F.
      ENDIF
  ENDIF
  
  lcsortcolumns = logrid.csavesortcolumns
  lcsortexpr    = logrid.csavesortexpr
  
  LOCAL lcalias
  lcalias = ALIAS()
  
  SELECT (logrid.RECORDSOURCE)
  
  WITH logrid
      IF !EMPTY(NVL(lcsortcolumns,""))
          i = 1
          DO WHILE !EMPTY(NVL(getarg(lcsortcolumns,i),""))
              lccolumn = getarg(lcsortcolumns,i)
              IF i = 1
                  .onsetorder(.&lccolumn)
              ELSE
                  .onsetorder(.&lccolumn, .F., .T.)
              ENDIF
  
              i = i + 1
          ENDDO
  
          IF lllocate
              IF !EMPTY(NVL(.csortcolumns,""))
                  lcsortexpr = .csortexpr
  
                  DO CASE
                  CASE UPPER(tcmodus) == "S"
                      lcsortexprval = EVAL(lcsortexpr)
                  OTHERWISE
                      IF VARTYPE(lcSortExprVal) = "C"
                          lcsortexprval = ALLTRIM(lcsortexprval)
                      ENDIF
                  ENDCASE
  
                  IF !EMPTY(NVL(lcsortexprval,""))
                      IF DESCENDING()
                          LOCATE ALL FOR &lcsortexpr <= lcsortexprval
                      ELSE
                          LOCATE ALL FOR &lcsortexpr >= lcsortexprval
                      ENDIF
  
                      IF !FOUND()  OR  EOF()
                          LOCATE
                      ENDIF
                  ENDIF
              ENDIF
          ENDIF
      ENDIF
  ENDWITH
  
  IF !EMPTY(lcalias) AND USED(lcalias)
      SELECT (lcalias)
  ENDIF
  
  

• cdataform.onpostsave - Called from onsave() after succesfull save operation

  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnPostSave",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  

• cdataform.Load

  DODEFAULT()
  
  IF TYPE("_VFX_FORM_WIZARD")="C"
      THISFORM.cworkalias = ''
      RETURN .T.
  ENDIF
  
  IF EMPTY(THISFORM.cworkalias)
      THISFORM.cworkalias = THISFORM.DATAENVIRONMENT.INITIALSELECTEDALIAS
  ENDIF
  IF !EMPTY(THISFORM.cworkalias) AND USED(THISFORM.cworkalias)
      THISFORM.lempty = EOF(THISFORM.cworkalias)
  ENDIF
  
  

• cdataform.onsetchilddata

  LPARAMETERS tcformname, toform
  
  

• cdataform.onparentrefresh

  LPARAMETERS tlonlydata, tlsetfocus
  
  ** Load Data
  IF ORDER() = "X" AND !EMPTY(THIS.cfilterexpr) AND ;
          FOR() <> UPPER(STRTRAN(THIS.cfilterexpr, " ", ""))
  
      LOCAL lckey, lcfilter
      lckey = KEY()
      lcfilter  = THIS.cfilterexpr
      lcidx = ORDER()
      IF !EMPTY(lckey)
          INDEX ON &lckey TO (lcidx) FOR &lcfilter ADDITIVE
          LOCATE
          THIS.lempty = EOF()
      ENDIF
  ENDIF
  
  LOCAL llrequerydone
  llrequerydone = THISFORM.REQUERY(.T.,.F.)
  
  IF llrequerydone AND THISFORM.lworkonview
      IF !EMPTY(NVL(THISFORM.cworkalias,""))
          SELECT (THISFORM.cworkalias)
  
          LOCAL lnrecno
          lnrecno = IIF(EOF(), 0, RECNO())
          LOCATE
  
          IF lnrecno > 0
              GO lnrecno
          ENDIF
      ENDIF
  ENDIF
  
  IF THISFORM.lhidewhenempty
      THISFORM.onemptyform()
  ENDIF
  
  IF !tlonlydata
      LOCAL lsetfocus
  
      lsetfocus = THISFORM.lsetfocus
  
      IF !tlsetfocus
          THISFORM.lsetfocus=.F.
      ENDIF
  
      IF THISFORM.lempty
          IF !THISFORM.lhidewhenempty
              THISFORM.REFRESH()
          ENDIF
      ELSE
          THISFORM.REFRESH()
      ENDIF
  
      THISFORM.lsetfocus=lsetfocus
  ENDIF
  
  

• cdataform.onloadposition

  DODEFAULT()
  
  LOCAL lcerror, j
  lcerror = ON('ERROR')
  
  _vfx_error = .F.
  
  ON ERROR _vfx_error = .T.
  
  FOR j = 1 TO THISFORM.CONTROLCOUNT
      IF LOWER(THISFORM.CONTROLS[j].BASECLASS) = 'grid'
          THISFORM.CONTROLS[j].onloadposition()
      ENDIF
  NEXT
  
  ON ERROR &lcerror
  
  RELEASE _vfx_error
  
  IF VARTYPE(goProgram)="O" AND  goprogram.ldebugmode
      SET ESCAPE ON
  
      ON SHUTDOWN
  
      ON ERROR
  ENDIF
  
  WAIT CLEAR
  
  

• cdataform.onsaveposition

  DODEFAULT()
  
  LOCAL lcerror, j
  lcerror = ON('ERROR')
  
  _vfx_error = .F.
  
  ON ERROR _vfx_error = .T.
  
  FOR j = 1 TO THISFORM.CONTROLCOUNT
      IF LOWER(THISFORM.CONTROLS[j].BASECLASS) = 'grid'
          THISFORM.CONTROLS[j].onsaveposition()
      ENDIF
  NEXT
  
  ON ERROR &lcerror
  
  RELEASE _vfx_error
  
  IF VARTYPE(goProgram)="O" AND  goprogram.ldebugmode
      SET ESCAPE ON
  
      ON SHUTDOWN
  
      ON ERROR
  ENDIF
  
  

• cdataform.Init

  LPARAMETERS tcarg
  
  IF TYPE("_VFX_FORM_WIZARD")="C"
      THISFORM.cworkalias = ''
      DODEFAULT()
      RETURN .T.
  ENDIF
  
  IF EMPTY(THISFORM.cworkalias)
      THISFORM.cworkalias = THISFORM.DATAENVIRONMENT.INITIALSELECTEDALIAS
  ENDIF
  
  IF EMPTY(THISFORM.cworkalias)
      =MESSAGEBOX("Initial Selected Alias is not specified!",16,THISFORM.NAME)
      RETURN .F.
  ENDIF
  
  IF !("VFXFUNC" $ SET('proc'))
      SET PROCEDURE TO PROGRAM\vfxfunc ADDITIVE
  ENDIF
  
  IF !("VFXOBJ.VCX" $ SET('classlib'))
      SET CLASSLIB TO lib\vfxobj.vcx ADDITIVE
  ENDIF
  
  IF !("VFXCTRL.VCX" $ SET('classlib'))
      SET CLASSLIB TO lib\vfxctrl.vcx ADDITIVE
  ENDIF
  
  IF !("VFXAPPL" $ SET('classlib'))
      SET CLASSLIB TO lib\vfxappl ADDITIVE
  ENDIF
  
  IF TYPE("goProgram")="O"
      IF goprogram.nhidewhenempty > 0
          THISFORM.lhidewhenempty = (goprogram.nhidewhenempty = 1)
      ENDIF
  ENDIF
  
  LOCAL k, lcstarttag, linitok
  
  IF EMPTY(THISFORM.cidxmgrclass)
      THISFORM.cidxmgrclass = "CIDXManager"
  ENDIF
  
  IF EMPTY(THISFORM.crecordmgrclass)
      THISFORM.crecordmgrclass = "CDataTableMgr"
  ENDIF
  
  THISFORM.ADDOBJECT('oIdxManager', THISFORM.cidxmgrclass)
  THISFORM.ADDOBJECT('oRecord'    , THISFORM.crecordmgrclass)
  
  THISFORM.oidxmanager.TOP    = THISFORM.HEIGHT
  THISFORM.oidxmanager.LEFT   = THISFORM.WIDTH
  
  THISFORM.orecord.TOP        = THISFORM.HEIGHT
  THISFORM.orecord.LEFT       = THISFORM.WIDTH
  
  IF THISFORM.lhidewhenempty
      IF EMPTY(THISFORM.cemptymessage)
          THISFORM.cemptymessage = msg_empty_view
      ENDIF
  
      WITH THISFORM.lblmsgempty
  
          .CAPTION = THISFORM.cemptymessage
  
          .TOP     = (THISFORM.HEIGHT - .HEIGHT)/2
          .LEFT    = (THISFORM.WIDTH  - .WIDTH )/2
  
          .ZORDER(1)
  
          .VISIBLE = .F.
      ENDWITH
  ENDIF
  
  linitok = DODEFAULT(tcarg)
  
  IF VARTYPE(goprogram)="O"
      IF !USED("vfxfopen")
          LOCAL frmname
          USE vfxfopen IN 0 SHARED AGAIN
          SELECT vfxfopen
          IF EMPTY(THIS.cscxname)
              frmname=UPPER(THIS.NAME)
              IF LEFT(frmname,3)=="FRM"
                  frmname=SUBSTR(frmname,4)
              ENDIF
          ELSE
              frmname=PADR(TRIM(STRTRAN(UPPER(THIS.cscxname),".SCX","")),32," ")
          ENDIF
          LOCATE FOR PADR(UPPER(FORM),32," ")==frmname
          IF FOUND()
              IF TYPE("vfxfopen.viewlevel")="N" AND !EMPTY(vfxfopen.viewlevel)
                  IF gu_userlevel > vfxfopen.viewlevel
                      ** make sure to cleanup correctly partially loaded form!
                      cform::DESTROY()
                      RETURN .F.
                  ENDIF
              ENDIF
              IF TYPE("vfxfopen.newlevel")="N" AND !EMPTY(vfxfopen.newlevel)
                  IF gu_userlevel <= vfxfopen.newlevel
                      THIS.lcaninsert=.T.
                      THIS.lcancopy=.T.
                  ELSE
                      THIS.lcaninsert=.F.
                      THIS.lcancopy=.F.
                  ENDIF
              ENDIF
              IF TYPE("vfxfopen.editlevel")="N" AND !EMPTY(vfxfopen.editlevel)
                  IF gu_userlevel <= vfxfopen.editlevel
                      THIS.lcanedit=.T.
                  ELSE
                      THIS.lcanedit=.F.
                  ENDIF
              ENDIF
              IF TYPE("vfxfopen.eraselevel")="N" AND !EMPTY(vfxfopen.eraselevel)
                  IF gu_userlevel <= vfxfopen.eraselevel
                      THIS.lcandelete=.T.
                  ELSE
                      THIS.lcandelete=.F.
                  ENDIF
              ENDIF
          ENDIF
          USE IN vfxfopen
      ENDIF
  ENDIF
  
  IF linitok
  
      THISFORM.coldtitle = THISFORM.CAPTION
  
      IF TYPE("goProgram.nAutoEditMode")="N"
          IF goprogram.nautoeditmode > 0
              THISFORM.lautoedit = (goprogram.nautoeditmode = 1)
          ENDIF
      ENDIF
  
      IF TYPE("goProgram.nAskToSave")="N"
          IF goprogram.nasktosave > 0
              THISFORM.lasktosave = (goprogram.nasktosave = 1)
          ENDIF
      ENDIF
  
      THISFORM.orecord.caliasname = THISFORM.cworkalias
  
      THISFORM.nformstatus = id_normal_mode
  
      THISFORM.onformstatuschange()
  
      IF !EMPTY(THISFORM.cworkalias)
          SELECT(THISFORM.cworkalias)
  
          lcstarttag = TAG()
  
          IF THISFORM.lusesetkeyasfilter
              IF !EMPTY(THISFORM.csetkeyindex)
                  SET ORDER TO TAG (THISFORM.csetkeyindex)
  *!*                ELSE
  *!*                    = MESSAGEBOX(ALIAS() +" - Table without index!",16,THISFORM.NAME)
  *!*                    RETURN .F.
              ENDIF
          ENDIF
  
          IF !THISFORM.lworkonview
  *!*                IF EMPTY(TAG())
  *!*                    IF tagcount() = 0
  *!*                        = MESSAGEBOX(ALIAS() +" - Table without index!",16,THISFORM.NAME)
  *!*                        RETURN .F.
  *!*                    ENDIF
  *!*                    SET ORDER TO 1
  *!*                ENDIF
  
              IF FILE(TAG()+".idx")
                  THISFORM.cworktag = ''
                  FOR k = 1 TO tagcount()
                      IF !FILE(TAG(k)+".idx")
                          THISFORM.cworktag = TAG(k)
                          EXIT
                      ENDIF
                  NEXT
              ELSE
                  THISFORM.cworktag = TAG()
              ENDIF
          ELSE
              THISFORM.cworktag = ''
          ENDIF
  
          THISFORM.oidxmanager.savetag()
  
          SELECT(THISFORM.cworkalias)
  
          SET ORDER TO TAG (lcstarttag)
  
          ** NoLoadData, NoRequery if lWorkOnView = .T.
  
          IF !EMPTY(THISFORM.cqueryarg)
              THISFORM.REQUERY(.T.,.F.)
          ELSE
              THISFORM.REQUERY(.F.,.F.)
          ENDIF
  
          IF TYPE("__VFX_PickField") # "U"
              THISFORM.opickfield = __vfx_pickfield
  
              IF pemstatus(THISFORM.opickfield,"oLinkForm",5)
                  THISFORM.opickfield.olinkform = THIS
              ENDIF
          ELSE
              THISFORM.opickfield = .NULL.
          ENDIF
  
          LOCAL lfoundit
  
          lfoundit = .F.
  
          IF TYPE("__VFX_PickRecLoc") # "U"
  
              IF (THISFORM.lworkonview)
                  * View positioning
                  THISFORM.jumpto(THISFORM.opickfield.creturnexpr, __vfx_pickrecloc)
              ELSE
                  IF TYPE("__VFX_FromValid") = "L" AND __vfx_fromvalid
                      THISFORM.jumpto(THISFORM.opickfield.creturnexpr, __vfx_pickrecloc)
                  ENDIF
  
                  LOCAL lctagname
  
                  lctagname = TAG()
  
                  IF TYPE("__VFX_PickTagName") != "U"
                      SET ORDER TO TAG (__vfx_picktagname)
  
                      IF !(TYPE("__VFX_FromValid") = "L" AND __vfx_fromvalid)
                          SEEK __vfx_pickrecloc
  
                          lfoundit = FOUND()
  
                          IF !FOUND()
                              LOCATE
                          ENDIF
                      ENDIF
  
                      IF !EMPTY(lctagname)
                          SET ORDER TO TAG (lctagname)
                      ENDIF
                  ENDIF
              ENDIF
  
              THISFORM.noldrecno = IIF(EOF() OR DELETE(), 0, RECNO())
  
              __vfx_pickrecloc  = ''
              __vfx_picktagname = ''
  
              RELEASE __vfx_pickrecloc, __vfx_picktagname
          ENDIF
  
          IF lfoundit
              IF TYPE("thisForm.pgfPageFrame")="O" AND TYPE("thisForm.nPageEdit")="N"
                  THISFORM.pgfpageframe.ACTIVEPAGE = THISFORM.npageedit
              ENDIF
          ENDIF
  
      ENDIF
  ENDIF
  
  IF THISFORM.lhidewhenempty
      WITH THISFORM.lblmsgempty
  
          .CAPTION = THISFORM.cemptymessage
  
          .TOP     = (THISFORM.HEIGHT - .HEIGHT)/2
          .LEFT    = (THISFORM.WIDTH  - .WIDTH )/2
  
          .ZORDER(1)
  
          .VISIBLE = THISFORM.lempty
      ENDWITH
  ENDIF
  
  IF VARTYPE(goProgram) = "U" AND TYPE("__VFX_Builder")="U"
      IF INLIST(THIS._vfxclassname,"CDataFormPage","COneToMany","CTableForm")
          PUBLIC gotoolbar
  
          IF !("VFXAPPL.VCX" $ SET('classlib'))
              SET CLASSLIB TO lib\vfxappl.vcx ADDITIVE
          ENDIF
  
          gotoolbar = CREATEOBJECT("CNavigatorBar")
  
          gotoolbar.DOCK(-1)    && No Docking
  
          gotoolbar.SHOW()
      ENDIF
  ENDIF
  
  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("CDataForm.Init",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  RETURN linitok
  
  

• cdataform.QueryUnload

  IF !"vfxhook" $ SET("procedure")
      SET PROCEDURE TO PROGRAM\vfxhook ADDITIVE
  ENDIF
  
  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("QueryUnload",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              NODEFAULT
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          NODEFAULT
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  SELECT (THISFORM.cworkalias)
  
  IF THISFORM.nformstatus <> id_normal_mode
  
      THISFORM.onwritebuffer()
  
      IF THISFORM.recordchanged() OR THISFORM.nformstatus = id_insert_mode
          IF !THISFORM.asktosave()
              ** Do Nothing
              NODEFAULT
              RETURN .F.
          ENDIF
      ELSE
          THISFORM.nformstatus = id_normal_mode
          THISFORM.CAPTION = THISFORM.coldtitle
          THISFORM.refreshtoolbar(.T.)
          THISFORM.onformstatuschange()
          THISFORM.REFRESH()
      ENDIF
  ELSE
      SET FILTER TO
  ENDIF
  
  IF TXNLEVEL() > 0
      ROLLBACK
  ENDIF
  
  LOCAL latable[1]
  
  latable = .F.
  
  =AUSED(latable)
  
  IF !EMPTY(latable)
      FOR j = 1 TO ALEN(latable,1)
          IF CURSORGETPROP("Buffering", latable[j,1]) != 1
              =TABLEREVERT(.T., latable[j,1])
          ENDIF
      NEXT
  ENDIF
  
  

• cdataform.Destroy

  DODEFAULT()
  
  IF THISFORM.lclosechildformonexit
      IF TYPE("thisForm.oFormList") = "O"
          THISFORM.oformlist.closeallchild()
          THISFORM.REMOVEOBJECT('oFormList')
      ENDIF
  ENDIF
  
  IF !ISNULL(THISFORM.opickfield)
  
      __vfx_pickfield   = .NULL.
  
      RELEASE __vfx_pickfield
  
      THISFORM.opickfield.GOTFOCUS()
  ENDIF
  
  THISFORM.opickfield = .NULL.
  
  IF VARTYPE(goProgram) = "U"
      IF INLIST(THIS._vfxclassname,"CDataFormPage","COneToMany","CTableForm")
          RELEASE gotoolbar
      ENDIF
  ENDIF
  
  IF TYPE("_VFX_FORM_WIZARD")="U"
      THISFORM.clearidx()
  ENDIF
  
  SET MESSAGE TO ""
  SET MESSAGE TO
  
  

• cdataform.onsetenv

  IF VARTYPE(goProgram)="O"
  
      IF !DBUSED(goprogram.cmaindatabase)
          OPEN DATABASE (goprogram.cdatadir+"\"+goprogram.cmaindatabase) SHARED
      ENDIF
  
      SET  DATABASE TO (goprogram.cdatadir+"\"+goprogram.cmaindatabase)
  ELSE
      LOCAL lcdatabase, ladata[1]
  
      = ADIR(ladata,"data\*.dbc","A")
  
      IF !EMPTY(ladata)
          lcdatabase = STRTRAN(LOWER(ladata[1,1]),".dbc","")
  
          OPEN DATA ("data\"+lcdatabase) SHARED
  
          SET DATA TO ("data\"+lcdatabase)
      ELSE
          lcdatabase = GETFILE('DBC')
  
          IF EMPTY(lcdatabase)
              RETURN .F.
          ENDIF
  
          OPEN DATA (lcdatabase) SHARED
  
          lcdatabase =  LEFT(lcdatabase,RAT(".",lcdatabase)-1)
          lcdatabase = SUBSTR(lcdatabase,RAT("\",lcdatabase)+1)
  
          SET DATA TO (lcdatabase)
      ENDIF
  ENDIF
  
  RETURN DODEFAULT()
  
  

• cdataform.Activate

  IF TYPE("thisform.activecontrol") = "O"                     AND ;
          pemstatus(THISFORM.ACTIVECONTROL.PARENT,'_vfxclassname',5) AND ;
          LOWER(THISFORM.ACTIVECONTROL.PARENT._vfxclassname) == "cpickfield" AND ;
          THISFORM.ACTIVECONTROL.PARENT.lrunform
  
      THISFORM.ACTIVECONTROL.PARENT.txtfield.SETFOCUS()
      NODEFAULT
      RETURN .T.
  ENDIF
  
  IF TYPE("thisform.activecontrol") = "O"                     AND ;
          pemstatus(THISFORM.ACTIVECONTROL,'_vfxclassname',5) AND ;
          LOWER(THISFORM.ACTIVECONTROL._vfxclassname) == "cpicktextbox" AND ;
          THISFORM.ACTIVECONTROL.lrunform
  
      THISFORM.ACTIVECONTROL.SETFOCUS()
      NODEFAULT
      RETURN .T.
  ENDIF
  
  DODEFAULT()
  
  IF THISFORM.nformstatus = 0
      IF DELETED()
          LOCATE
  
          IF EOF()
              THISFORM.lempty = .T.
          ENDIF
  
          IF THISFORM.lempty
              THISFORM.noldrecno = 0
          ELSE
              THISFORM.noldrecno = IIF(EOF() OR DELETED(), 0, RECNO())
          ENDIF
      ENDIF
  
      IF THISFORM.lhidewhenempty
          THISFORM.onemptyform()
      ENDIF
      IF THISFORM.lworkonview
          THISFORM.REFRESH()
      ENDIF
  ENDIF
  
  ** check whether this form has been called from picklist with new option
  IF TYPE("__VFX_PickNew") # "U"
  
      THISFORM.oninsert()
      RELEASE __vfx_picknew
  ENDIF
  
  NODEFAULT
  
  

• cdataform.Resize

  DODEFAULT()
  
  IF THISFORM.lhidewhenempty
      WITH THISFORM.lblmsgempty
  
          .CAPTION = THISFORM.cemptymessage
  
          .TOP     = (THISFORM.HEIGHT - .HEIGHT)/2
          .LEFT    = (THISFORM.WIDTH  - .WIDTH )/2
  
          .ZORDER(1)
  
          .VISIBLE = THISFORM.lempty
      ENDWITH
  ENDIF
  
  

cdataform.lblMsgEmpty

Name	Initial value	Comment
ldonthidelistpage	.f.	Defines whether the list page should not be hidden when editing. See also: cfoxapp.ndonthidelistpage
lenterisedit	.f.	Specifies if the OnKeyEnter() method should call OnEdit() or simply go to the first Page Edit
lmultipage	.T.	.T. if PageCount > 0
noldpage	0	Reserved. Stores the previously selected page.
npageedit	1	Page number one for editing of fields. Usually page 1.
npagelist	0	Page used for the grid. Usually last page (pagecount)
nstartpage	-1	Specifies which page initially get's displayed. Usually page number 1.

Methods

• cdataformpage.onnextpage - Called when switching to the next page.

  THIS.dispbegin()
  
  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnNextPage",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  WITH THIS.pgfpageframe
      IF .ACTIVEPAGE < .PAGECOUNT
          .ACTIVEPAGE = .ACTIVEPAGE + 1
  
          .SETALL('ForeColor',RGB(0,0,0), 'Page')
          .PAGES[.ActivePage].FORECOLOR = RGB(0,0,255)
  
          .tabrefresh(.T.)
      ENDIF
  ENDWITH
  
  THIS.dispend(.T.)
  
  

• cdataformpage.onprevpage - Called when switching to the previous page.

  THIS.dispbegin()
  
  IF THISFORM.lusehook
      LOCAL luhookvalue
      luhookvalue = THISFORM.oneventhook("OnPrevPage",THIS,THISFORM)
      DO CASE
      CASE VARTYPE(luhookvalue)="L"
          IF !luhookvalue
              RETURN .T.
          ENDIF
      CASE VARTYPE(luhookvalue)="N"
          RETURN luhookvalue=0
      ENDCASE
  ENDIF
  
  WITH THIS.pgfpageframe
      IF .ACTIVEPAGE > 1
          .ACTIVEPAGE = .ACTIVEPAGE - 1
  
          .SETALL('ForeColor',RGB(0,0,0), 'Page')
          .PAGES[.ActivePage].FORECOLOR = RGB(0,0,255)
  
          .tabrefresh(.T.)
      ENDIF
  ENDWITH
  
  THIS.dispend(.T.)
  
  

• cdataformpage.Init

  LPARAMETERS tcarg
  
  LOCAL linitok
  
  THISFORM.nstartpage = -1
  
  linitok = DODEFAULT(tcarg)
  
  IF EMPTY(THISFORM.cworkalias)
      RETURN
  ENDIF
  
  IF linitok
      IF VARTYPE(goProgram)="O"
          IF goprogram.ndonthidelistpage > 0
              THISFORM.ldonthidelistpage = (goprogram.ndonthidelistpage = 1)
          ENDIF
      ENDIF
  
      THIS.lmultipage = .F.
  
      IF !THIS.pgfpageframe.lusegrid
          THIS.npagelist = 0
      ENDIF
  
      IF THIS.pgfpageframe.PAGECOUNT > 1
          THIS.lmultipage = .T.
  
          IF THISFORM.nstartpage < 1
              IF VARTYPE(gu_FirstView)="N"
                  IF gu_firstview > 1
                      THISFORM.nstartpage = THIS.npagelist
                  ENDIF
              ENDIF
          ENDIF
      ENDIF
  
      IF THISFORM.nstartpage  < 1
          THISFORM.nstartpage = 1
      ENDIF
  
      THIS.pgfpageframe.ACTIVEPAGE = THISFORM.nstartpage
      THIS.noldpage                = THISFORM.nstartpage
  
      IF THIS.npagelist # 0
          IF TYPE("this.pgfPageFrame.Pages[thisForm.nPageList].grdGrid") = "O"
              THISFORM.pgfpageframe.PAGES[this.nPageList].grdgrid.onsetorder()
          ENDIF
      ENDIF
  
  ENDIF
  
  RETURN linitok
  
  

• cdataformpage.clearidx

  IF TYPE("thisForm.oIdxManager.aIndexList") <> "U"
      = ACOPY(THISFORM.oidxmanager.aindexlist, latempidx)
  ENDIF
  
  DODEFAULT()
  
  LOCAL lopageframe, j, k, lccontrolname, locurrentcontrol
  
  lopageframe = THISFORM.pgfpageframe
  
  FOR j = 1 TO lopageframe.PAGECOUNT
      FOR k = 1 TO lopageframe.PAGES[j].CONTROLCOUNT
          IF LOWER(lopageframe.PAGES[j].CONTROLS[k].BASECLASS) = 'grid' AND ;
                  pemstatus(lopageframe.PAGES[j].CONTROLS[k],'_VFXClassName',5) AND ;
                  LOWER(lopageframe.PAGES[j].CONTROLS[k]._vfxclassname) = 'cgrid'
  
              logrid                = lopageframe.PAGES[j].CONTROLS[k]
  
              IF TYPE("goProgram.lremakeidxafterclear")="L" AND goprogram.lremakeidxafterclear
                  logrid.csavesortcolumns    = logrid.csortcolumns
                  logrid.csavesortexpr    = logrid.csortexpr
              ENDIF
  
  
              logrid.csortcolumns    = ""
              logrid.csortexpr    = ""
  
              IF TYPE("goProgram.nShowGridOrderType")="N" AND goprogram.nshowgridordertype = 1    && Header
  
                  logrid.SETALL('FontUnderline', .F., 'Header')
  
              ELSE    && Colors
  
                  IF logrid.ctitlecolor = -1
                      IF TYPE("logrid.Columns[1].Header1") = "O"
                          logrid.ctitlecolor = logrid.COLUMNS[1].header1.BACKCOLOR
                      ELSE
                          logrid.ctitlecolor = RGB(192,192,192)
                      ENDIF
                  ENDIF
  
                  logrid.SETALL('BackColor', logrid.ctitlecolor, 'Header')
  
              ENDIF
  
              FOR lni = 1 TO logrid.COLUMNCOUNT
  
                  IF TYPE("logrid.columns[lni].header1") = "O" AND ;
                          CHR(160) $ logrid.COLUMNS[lni].header1.CAPTION
                      WITH logrid.COLUMNS[lni].header1
                          .CAPTION    = SUBSTR(.CAPTION, 1, AT(CHR(160), .CAPTION) -1)
                      ENDWITH
                  ENDIF
  
                  lccontrolname    = logrid.COLUMNS[lni].CURRENTCONTROL
                  locurrentcontrol = logrid.COLUMNS[lni].&lccontrolname
  
                  IF TYPE("loCurrentControl") = "O"
                      WITH locurrentcontrol
                          IF TYPE(".tag") = "C" AND TYPE("laTempIDX") <> "U" AND ;
                                  ASCAN(latempidx,.TAG) > 0
                              .TAG = ""
                          ENDIF
                      ENDWITH
                  ENDIF
  
              NEXT lni
  
          ENDIF
      NEXT
  NEXT
  
  IF VARTYPE(laTempIDX) <> "U"
      RELEASE ARRAY latempidx
  ENDIF
  
  

• cdataformpage.ondelete

  SELECT (THISFORM.cworkalias)
  RETURN DODEFAULT()
  
  

• cdataformpage.onedit

  THIS.noldpage = THIS.pgfpageframe.ACTIVEPAGE
  
  IF THIS.noldpage = THIS.npagelist
      THIS.pgfpageframe.ACTIVEPAGE = THISFORM.npageedit
      THIS.pgfpageframe.PAGES[thisForm.nPageEdit].REFRESH()
  ENDIF
  
  IF DODEFAULT()
      IF TYPE("thisForm.nPageList") = "N" AND THISFORM.npagelist > 0
          IF TYPE("this.pgfPageFrame.pages[thisForm.nPageList].grdGrid") = "O"
              THIS.pgfpageframe.PAGES[thisForm.nPageList].grdgrid.ENABLED = .F.
          ENDIF
          IF !THISFORM.ldonthidelistpage
              THISFORM.pgfpageframe.PAGES[thisform.npagelist].ENABLED = .F.
          ENDIF
      ENDIF
      THIS.pgfpageframe.tabrefresh()
  
      RETURN .T.
  ENDIF
  
  RETURN .F.
  
  

• cdataformpage.oninsert

  LOCAL lretcode
  
  THIS.dispbegin()
  
  THIS.noldpage = THIS.pgfpageframe.ACTIVEPAGE
  
  THIS.pgfpageframe.ACTIVEPAGE = THISFORM.npageedit
  
  lretcode = DODEFAULT()
  
  IF lretcode
      IF TYPE("thisForm.nPageList") = "N" AND THISFORM.npagelist > 0
          IF TYPE("this.pgfPageFrame.pages[thisForm.nPageList].grdGrid") = "O"
              THIS.pgfpageframe.PAGES[thisForm.nPageList].grdgrid.ENABLED = .F.
          ENDIF
          IF !THISFORM.ldonthidelistpage
              THISFORM.pgfpageframe.PAGES[thisform.npagelist].ENABLED = .F.
          ENDIF
      ENDIF
  
      THISFORM.setobjectfocus()
  
      THIS.pgfpageframe.tabrefresh(.T.)
  ELSE
      THIS.pgfpageframe.ACTIVEPAGE = THIS.noldpage
  ENDIF
  
  THIS.dispend()
  
  RETURN lretcode
  
  

• cdataformpage.onloadposition

  DODEFAULT()
  
  LOCAL lopageframe, j
  
  lopageframe = THISFORM.pgfpageframe
  
  IF RESOURCE.PAGE > 0 AND RESOURCE.PAGE <= lopageframe.PAGECOUNT
      THISFORM.nstartpage = RESOURCE.PAGE
  ELSE
      THISFORM.nstartpage = -1
  ENDIF
  
  lopageframe = THISFORM.pgfpageframe
  
  LOCAL lcerror
  lcerror = ON('ERROR')
  
  _vfx_error = .F.
  
  ON ERROR _vfx_error = .T.
  
  FOR j = 1 TO lopageframe.PAGECOUNT
      FOR k = 1 TO lopageframe.PAGES[j].CONTROLCOUNT
          IF LOWER(lopageframe.PAGES[j].CONTROLS[k].BASECLASS) = 'grid' AND ;
                  pemstatus(lopageframe.PAGES[j].CONTROLS[k],'_VFXClassName',5) AND ;
                  (LOWER(lopageframe.PAGES[j].CONTROLS[k]._vfxclassname) = 'cgrid' OR ;
                  LOWER(lopageframe.PAGES[j].CONTROLS[k]._vfxclassname) = 'cchildgrid')
              lopageframe.PAGES[j].CONTROLS[k].onloadposition()
          ENDIF
      NEXT
  NEXT
  
  ON ERROR &lcerror
  
  RELEASE _vfx_error
  
  IF VARTYPE(goProgram)="O" AND  goprogram.ldebugmode
      SET ESCAPE ON
  
      ON SHUTDOWN
  
      ON ERROR
  ENDIF
  
  

• cdataformpage.onsave

  LPARAMETERS tlnotrefresh, tlalltables
  
  SELECT (THISFORM.cworkalias)
  
  IF TYPE("thisForm.nPageList") = "N" AND THISFORM.npagelist > 0
      IF TYPE("this.pgfPageFrame.pages[thisForm.nPageList].grdGrid") = "O"
          THIS.pgfpageframe.PAGES[thisForm.nPageList].grdgrid.ENABLED = .T.
      ENDIF
      THIS.pgfpageframe.PAGES[thisForm.nPageList].ENABLED = .T.
  ENDIF
  
  IF TYPE("goprogram") = "O" AND goprogram.lautorefreshonsave
      FOR i=1  TO  ALEN(THIS.pgfpageframe.aneedrefresh)
          IF THISFORM.pgfpageframe.aneedrefresh(i)
              IF i <> THISFORM.npagelist
                  THISFORM.pgfpageframe.PAGES(i).REFRESH()
                  THIS.pgfpageframe.aneedrefresh(i) = .F.
              ENDIF
          ENDIF
      ENDFOR
  ENDIF
  
  IF !DODEFAULT(tlnotrefresh,.T.)
      IF TYPE("thisForm.nPageList") = "N" AND THISFORM.npagelist > 0
          IF TYPE("this.pgfPageFrame.pages[thisForm.nPageList].grdGrid") = "O"
              THIS.pgfpageframe.PAGES[thisForm.nPageList].grdgrid.ENABLED = .F.
          ENDIF
          IF !THISFORM.ldonthidelistpage
              THISFORM.pgfpageframe.PAGES[thisform.npagelist].ENABLED = .F.
          ENDIF
      ENDIF
      RETURN .F.
  ENDIF
  
  IF !tlnotrefresh
      THISFORM.REFRESH()
  ENDIF
  
  THIS.pgfpageframe.tabrefresh()
  
  

• cdataformpage.onsaveposition

  DODEFAULT()
  
  LOCAL lopageframe, j
  
  lopageframe = THISFORM.pgfpageframe
  
  REPLACE RESOURCE.PAGE WITH lopageframe.ACTIVEPAGE
  
  LOCAL lcerror
  lcerror = ON('ERROR')
  
  _vfx_error = .F.
  
  ON ERROR _vfx_error = .T.
  
  FOR j = 1 TO lopageframe.PAGECOUNT
      FOR k = 1 TO lopageframe.PAGES[j].CONTROLCOUNT
          IF LOWER(lopageframe.PAGES[j].CONTROLS[k].BASECLASS) = 'grid' AND ;
                  pemstatus(lopageframe.PAGES[j].CONTROLS[k],'_VFXClassName',5) AND ;
                  (LOWER(lopageframe.PAGES[j].CONTROLS[k]._vfxclassname) = 'cgrid' OR ;
                  LOWER(lopageframe.PAGES[j].CONTROLS[k]._vfxclassname) = 'cchildgrid')
              lopageframe.PAGES[j].CONTROLS[k].onsaveposition()
          ENDIF
      NEXT
  NEXT
  
  ON ERROR &lcerror
  
  RELEASE _vfx_error
  
  IF VARTYPE(goProgram)="O" AND  goprogram.ldebugmode
      SET ESCAPE ON
  
      ON SHUTDOWN
  
      ON ERROR
  ENDIF
  
  

• cdataformpage.onundo

  LPARAMETERS tlnotrefresh
  
  SELECT (THISFORM.cworkalias)
  
  IF TYPE("thisForm.nPageList") = "N" AND THISFORM.npagelist > 0
      IF TYPE("this.pgfPageFrame.pages[thisForm.nPageList].grdGrid") = "O"
          THIS.pgfpageframe.PAGES[thisForm.nPageList].grdgrid.ENABLED = .T.
      ENDIF
      THIS.pgfpageframe.PAGES[thisForm.nPageList].ENABLED = .T.
  ENDIF
  
  IF !DODEFAULT(.T.)
      IF TYPE("thisForm.nPageList") = "N" AND THISFORM.npagelist > 0
          IF TYPE("this.pgfPageFrame.pages[thisForm.nPageList].grdGrid") = "O"
              THIS.pgfpageframe.PAGES[thisForm.nPageList].grdgrid.ENABLED = .F.
          ENDIF
          IF !THISFORM.ldonthidelistpage
              THISFORM.pgfpageframe.PAGES[thisform.npagelist].ENABLED = .F.
          ENDIF
      ENDIF
      RETURN .F.
  ENDIF
  
  IF !tlnotrefresh
      THISFORM.REFRESH()
  ENDIF
  
  THIS.pgfpageframe.tabrefresh()
  
  

• cdataformpage.setobjectfocus

  =setfirstfocus(THISFORM.pgfpageframe)
  
  

• cdataformpage.onemptyform

  IF THISFORM.lhidewhenempty
      DODEFAULT()
      THISFORM.pgfpageframe.VISIBLE = !THISFORM.lempty
  ENDIF
  
  

• cdataformpage.oncopy

  LOCAL lretcode
  
  THIS.dispbegin()
  
  THIS.noldpage = THIS.pgfpageframe.ACTIVEPAGE
  
  THIS.pgfpageframe.ACTIVEPAGE = THISFORM.npageedit
  
  lretcode = DODEFAULT()
  
  IF lretcode
      IF TYPE("thisForm.nPageList") = "N" AND THISFORM.npagelist > 0
          IF TYPE("this.pgfPageFrame.pages[thisForm.nPageList].grdGrid") = "O"
              THIS.pgfpageframe.PAGES[thisForm.nPageList].grdgrid.ENABLED = .F.
          ENDIF
          IF !THISFORM.ldonthidelistpage
              THISFORM.pgfpageframe.PAGES[thisform.npagelist].ENABLED = .F.
          ENDIF
      ENDIF
  
      THISFORM.setobjectfocus()
      THISFORM.REFRESH()
      THIS.pgfpageframe.tabrefresh(.T.)
  ENDIF
  
  THIS.dispend()
  
  RETURN lretcode
  
  

• cdataformpage.onrecordmove

  THISFORM.pgfpageframe.aneedrefresh = .T.
  
  DODEFAULT()
  
  

cdataformpage.pgfPageFrame

• cdataformpage.pgfPageFrame.Refresh

  if this.Visible
      this.TabRefresh(.f.)
      if this.ActivePage = thisForm.nPageList
          if type("this.Pages[this.ActivePage].grdGrid")="O"
              local lFromValid
              lFromValid = .F.
              
              if type("__VFX_FromValid")="L" and __VFX_FromValid
                  lFromValid = .T.
              endif
              
              if thisForm.lSetFocus and !lFromValid
                  this.Pages[this.ActivePage].grdGrid.SetFocus()
              endif
          endif
      endif
  endif
  

cdataformpage.pgfPageFrame.Page1

cdataformpage.lblMsgEmpty

• cdataformpagebar.refreshtoolbar

  LPARAMETERS tlarg1
  
  DODEFAULT(tlarg1)
  
  THISFORM.cntbuttonbar.REFRESH()
  
  

cdataformpagebar.cntButtonBar

cdataformpagebar.cntButtonBar.cmdBottom

cdataformpagebar.cntButtonBar.cmdClose

cdataformpagebar.cntButtonBar.cmdDelete

cdataformpagebar.cntButtonBar.cmdEdit

• cdataformpagebar.cntButtonBar.cmdEdit.Click

  IF THISFORM.onedit()
      THISFORM.setobjectfocus()
      NODEFAULT
  ENDIF
  
  

cdataformpagebar.cntButtonBar.cmdMore

cdataformpagebar.cntButtonBar.cmdNew

• cdataformpagebar.cntButtonBar.cmdNew.Click

  THISFORM.oninsert()
  THISFORM.setobjectfocus()
  NODEFAULT
  
  

cdataformpagebar.cntButtonBar.cmdNext

cdataformpagebar.cntButtonBar.cmdPrev

cdataformpagebar.cntButtonBar.cmdSave

• cdataformpagebar.cntButtonBar.cmdSave.Click

  THISFORM.onsave()
  
  IF THISFORM.pgfpageframe.lusegrid AND THISFORM.npagelist > 0
      IF THISFORM.pgfpageframe.ACTIVEPAGE = THISFORM.npagelist
          LOCAL lfromvalid
          lfromvalid = .F.
  
          IF VARTYPE(__VFX_FromValid)="L" AND __vfx_fromvalid
              lfromvalid = .T.
          ENDIF
  
          IF !lfromvalid
              THISFORM.pgfpageframe.PAGES[thisForm.nPageList].grdgrid.SETFOCUS()
          ENDIF
      ENDIF
  ENDIF
  
  NODEFAULT
  
  

cdataformpagebar.cntButtonBar.cmdSearch

cdataformpagebar.cntButtonBar.cmdTop

cdataformpagebar.cntButtonBar.cmdUndo

• cdataformpagebar.cntButtonBar.cmdUndo.Click

  THISFORM.onundo()
  
  IF THISFORM.pgfpageframe.lusegrid AND THISFORM.npagelist > 0
      IF THISFORM.pgfpageframe.ACTIVEPAGE = THISFORM.npagelist
          LOCAL lfromvalid
          lfromvalid = .F.
  
          IF VARTYPE(__VFX_FromValid)="L" AND __vfx_fromvalid
              lfromvalid = .T.
          ENDIF
  
          IF !lfromvalid
              THISFORM.pgfpageframe.PAGES[thisForm.nPageList].grdgrid.SETFOCUS()
          ENDIF
      ENDIF
  ENDIF
  
  NODEFAULT
  
  

cdataformpagebar.lblMsgEmpty

cdataformpagebar.pgfPageFrame

cdataformpagebar.pgfPageFrame.Page1

cedithelp.cmdCancel

• cedithelp.cmdCancel.Click

  thisform.uretcode=0
  thisform.release
  

cedithelp.cmdOK

• cedithelp.cmdOK.Click

  thisform.uretcode=1
  thisform.release
  

cedithelp.edtText

cedithelp.Clabel1

cedithelp.Clabel2

cedithelp.Clabel3

cedithelp.Clabel4

cedithelp.Clabel5

cedithelp.Clabel6

cedithelp.txtBook

cedithelp.txtBook2

cedithelp.txtChapter

cedithelp.txtIndex

cedithelp.txtTitle

• cgaugewin.setmaxvalue - Sets the max value for gauge

  LPARAMETERS tnvalue
  
  THIS.ctrgauge.setmaxvalue(tnvalue)
  
  

• cgaugewin.setmessage - Sets the message text

  LPARAMETERS tcvalue
  
  THIS.lbltext.CAPTION = ALLTRIM(tcvalue)
  
  

• cgaugewin.settext - Sets text for gauge

  LPARAMETERS tcvalue
  
  THIS.ctrgauge.settext(tcvalue)
  
  

• cgaugewin.setvalue - Set the current value for the gauge

  LPARAMETERS tnvalue
  
  THIS.ctrgauge.setvalue(tnvalue)
  
  

• cgaugewin.Init

  LPARAMETERS tnmaxvalue, tctitle
  
  WITH THIS
      .langsetup()
  
      .AUTOCENTER = .T.
  
      .ctrgauge.setmaxvalue(tnmaxvalue)
      .ctrgauge.settext(tctitle)
  
      .SETALL('FontSize',8      )
      .SETALL('FontName','Arial')
  
      .BACKCOLOR = EVAL("rgb("+SUBSTR(RGBSCHEME(1,2),AT(",",RGBSCHEME(1,2),3)+1))
  
      .SETALL('BackColor',.BACKCOLOR)
  ENDWITH
  
  

cgaugewin.ctrGauge

cgaugewin.ctrGauge.LineDown

cgaugewin.ctrGauge.LineLeft

cgaugewin.ctrGauge.LineRight

cgaugewin.ctrGauge.Shape1

cgaugewin.ctrGauge.Shape10

cgaugewin.ctrGauge.Shape11

cgaugewin.ctrGauge.Shape12

cgaugewin.ctrGauge.Shape13

cgaugewin.ctrGauge.Shape14

cgaugewin.ctrGauge.Shape15

cgaugewin.ctrGauge.Shape16

cgaugewin.ctrGauge.Shape17

cgaugewin.ctrGauge.Shape18

cgaugewin.ctrGauge.Shape19

cgaugewin.ctrGauge.Shape2

cgaugewin.ctrGauge.Shape20

cgaugewin.ctrGauge.Shape3

cgaugewin.ctrGauge.Shape4

cgaugewin.ctrGauge.Shape5

cgaugewin.ctrGauge.Shape6

cgaugewin.ctrGauge.Shape7

cgaugewin.ctrGauge.Shape8

cgaugewin.ctrGauge.Shape9

cgaugewin.ctrGauge.lblText

cgaugewin.ctrGauge.lineUp

cgaugewin.lblText