Name	Initial value	Comment
false	0
oexcel	.NULL.
true	-1
xlautomatic	-4105
xlcontinuous	1
xldiagonaldown	5
xldiagonalup	6
xledgebottom	9
xledgeleft	7
xledgeright	10
xledgetop	8
xlinsidehorizontal	12
xlinsidevertical	11
xlmaximized	-1434	Maximized Constant
xlmedium	-4138
xlminimized	-1440	Minimize Constant
xlnone	-4142
xlthin	2
xltop	-4160

Methods

• excel.activatesheet

  LPARAMETERS tcwb, tcsheet
  THIS.oexcel.workbooks(tcwb).worksheets(tcsheet).ACTIVATE()
  
  

• excel.closeexcel

  IF (!ISNULL(THIS.oexcel))
      THIS.oexcel.QUIT()
      THIS.oexcel = .NULL.
  ENDIF
  
  

• excel.closeworkbook

  LPARAMETERS tcwb
  
  WITH THIS.oexcel
      IF EMPTY(tcwb)
          .activeworkbook.CLOSE()
      ELSE
          .workbooks(tcwb).CLOSE()
      ENDIF
  ENDWITH
  
  

• excel.copysheet

  * tcTargetWorkbook passed by reference !
  LPARAMETERS tcsourcewb, tcsourcesheet, tctargetwb
  
  WITH THIS.oexcel
  
      IF (!EMPTY(tctargetwb))
          * copy to existing Workbook
          .sheets(tcsourcesheet).COPY(.workbooks(tctargetwb).sheets(1))
      ELSE
          * copy to a new Workbook
          .sheets(tcsourcesheet).SELECT
          .sheets(tcsourcesheet).COPY
          tctargetwb = .activeworkbook.FULLNAME
      ENDIF
  
  ENDWITH
  
  RETURN THIS.sheetname(tctargetwb)
  
  

• excel.getvalue

  LPARAMETERS tcrange
  LOCAL lcretval
  
  WITH THIS.oexcel
      lcretval = .activesheet.RANGE(tcrange).VALUE
  ENDWITH
  
  RETURN lcretval
  
  

• excel.lockcells

  LPARAMETERS tcwb, tcsheet, tcrange, tcpwd, tllock
  
  WITH THIS.oexcel
      IF (EMPTY(tcwb))
          tcwb = THIS.workbookname()
      ENDIF
  
      IF (EMPTY(tcsheet))
          tcsheet = THIS.sheetname(tcwb)
      ENDIF
  
      .workbooks(tcwb).worksheets(tcsheet).RANGE(tcrange).locked = tllock
  ENDWITH
  
  

• excel.openexcel

  LPARAMETERS tlforcenewinstance, tlvisible, tnwindowstate
  LOCAL llretval, lcerror, llgetobjectfailed
  
  WAIT WINDOW msg_openexcel NOWAIT
  
  IF !tlforcenewinstance
      llgetobjectfailed = .F.
      lcerror           = ON("error")
      ON ERROR llgetobjectfailed=.T.
      THIS.oexcel = GETOBJECT(, "Excel.Application")
      ON ERROR &lcerror
  ENDIF
  
  IF llgetobjectfailed OR tlforcenewinstance
      llgetobjectfailed = .F.
      lcerror           = ON("error")
      ON ERROR llgetobjectfailed=.T.
      THIS.oexcel = CREATEOBJECT("Excel.Application")
      ON ERROR &lcerror
  ENDIF
  
  WAIT CLEAR
  
  IF (TYPE("this.oExcel")="O" AND !ISNULL(THIS.oexcel))
      IF (tlvisible)
          THIS.oexcel.VISIBLE = .T.
      ENDIF
  
      llretval = .T.
  ELSE
      =MESSAGEBOX(msg_excelfailed,16,"Excel")
      llretval = .F.
  ENDIF
  
  RETURN llretval
  
  

• excel.openworkbook

  LPARAMETERS tcfilename, tlonlywhenclosed, tcwb
  
  IF tlonlywhenclosed
      IF TYPE("this.oExcel.Workbooks(tcWB)") = "O"
          RETURN .T.
      ENDIF
  ENDIF
  
  WITH THIS.oexcel
      .workbooks.OPEN(tcfilename)
  ENDWITH
  
  

• excel.protectsheet

  LPARAMETERS tcwb, tcsheet, tcpwd
  
  WITH THIS.oexcel
      IF (EMPTY(tcwb))
          tcwb = THIS.workbookname()
      ENDIF
  
      IF (EMPTY(tcsheet))
          tcsheet = THIS.sheetname()
      ENDIF
  
      .workbooks(tcwb).worksheets(tcsheet).PROTECT(tcpwd, .T., .T., .T.)
  ENDWITH
  
  

• excel.release - Releases a FormSet or Form from memory.

  RELEASE THIS
  
  

• excel.saveasworkbook

  LPARAMETERS tcwb, tcsheet, tcfilename, tcfileformat
  
  IF (EMPTY(tcfileformat))
      tcfileformat = "NORMAL"
  ENDIF
  
  tcfileformat = UPPER(tcfileformat)
  
  WITH THIS.oexcel
  
      .workbooks(tcwb).worksheets(tcsheet).ACTIVATE()
  
      DO CASE
      CASE tcfileformat == "EXCEL4WORKBOOK"
          .workbooks(tcwb).SAVEAS(tcfilename, 35)        && saves current workbook
      CASE tcfileformat == "EXCEL4"
          .workbooks(tcwb).SAVEAS(tcfilename, 33)        && saves only the active Sheet
      CASE tcfileformat == "EXCEL5"
          .workbooks(tcwb).SAVEAS(tcfilename, 39)        && saves all Sheets
      CASE tcfileformat == "NORMAL"
          .workbooks(tcwb).SAVEAS(tcfilename, -4143)    && saves only the active Sheet
      CASE tcfileformat == "TEXT"
          .workbooks(tcwb).SAVEAS(tcfilename, 0)        && saves only the active Sheet
      CASE tcfileformat == "WK1"
          .workbooks(tcwb).SAVEAS(tcfilename, 5)        && saves only the active Sheet
      CASE tcfileformat == "WK3"
          .workbooks(tcwb).SAVEAS(tcfilename, 15)        && saves only the active Sheet
      CASE tcfileformat == "WK4"
          .workbooks(tcwb).SAVEAS(tcfilename, 38)        && saves only the active Sheet
      CASE tcfileformat == "CSV"
          .workbooks(tcwb).SAVEAS(tcfilename, 6)        && saves only the active Sheet
      ENDCASE
  
  ENDWITH
  
  

• excel.setvalue

  LPARAMETERS tcrange, tcvalue, tllock
  
  IF PARAMETERS() = 3
      THIS.lockrange(tcrange, tllock)
  ENDIF
  
  THIS.oexcel.activesheet.RANGE(tcrange).VALUE = tcvalue
  
  
  

• excel.sheetname

  LPARAMETERS tcworkbookname
  LOCAL lcsheetname
  
  lcsheetname = ""
  
  IF (EMPTY(tcworkbookname))
      tcworkbookname = THIS.workbookname(.T.)
  ENDIF
  
  IF (!EMPTY(tcworkbookname))
      lcsheetname = THIS.oexcel.workbooks(tcworkbookname).activesheet.NAME
  ENDIF
  
  RETURN lcsheetname
  
  

• excel.unprotectsheet

  LPARAMETERS tcwb, tcsheet, tcpassword
  
  THIS.oexcel.workbooks(tcwb).worksheets(tcsheet).unprotect(tcpassword)
  
  

• excel.workbookname

  LPARAMETERS tlshort
  
  LOCAL lcworkbookname
  
  lcworkbookname = ""
  
  WITH THIS.oexcel
      IF (.workbooks.COUNT > 0)
          IF tlshort
              lcworkbookname = .activeworkbook.NAME
          ELSE
              lcworkbookname = .activeworkbook.FULLNAME
          ENDIF
      ELSE
          lcworkbookname = ""
      ENDIF
  ENDWITH
  
  RETURN lcworkbookname
  
  

• excel.setwindowstate - Sets the Status of the Window (Minimized, Maximized)

  LPARAMETERS tnwindowstate
  
  THIS.oexcel.WINDOWSTATE = tnwindowstate
  
  

• excel.addworkbook

  LPARAMETERS tctemplate
  
  LOCAL lcworkbookname
  
  IF VARTYPE(THIS.oexcel)="O"
      WITH THIS.oexcel
          IF EMPTY(tctemplate)
              .workbooks.ADD()
          ELSE
              .workbooks.ADD(tctemplate)
          ENDIF
          lcworkbookname = .activeworkbook.FULLNAME
      ENDWITH
  ENDIF
  RETURN lcworkbookname
  
  

• excel.setcolorpattern

  LPARAMETERS tcrange, tncolindex, tnpattern, tnpatterncolindex
  
  WITH THIS.oexcel
      .activesheet.RANGE(tcrange).interior.colorindex = tncolindex                     && = 44
      .activesheet.RANGE(tcrange).interior.PATTERN = tnpattern                         && = 1
      .activesheet.RANGE(tcrange).interior.patterncolorindex = tnpatterncolindex        && -4105
  ENDWITH
  
  

• excel.passthrough

  LPARAMETERS tccommand
  
  WITH THIS.oexcel
      &tccommand
  ENDWITH
  
  

• excel.setformula

  LPARAMETERS tcrange, tcformula
  
  IF LEFT(tcformula,1) = "="
      THIS.oexcel.activesheet.RANGE(tcrange).formula = tcformula
  ENDIF
  
  

• excel.autofill

  LPARAMETERS tcsourcerange, tctargetrange
  LOCAL lccommand
  
  lccommand = 'Set sourceRange = .ActiveSheet.Range("'+tcsourcerange+'") : ' +;
      'set fillrange = .activesheet.range("'+tctargetrange+'") : ' +;
      'sourcerange.autofill destination:=fillrange'
  
  THIS.passthrough(lccommand)
  
  

• excel.getrow

  LPARAMETERS tcref
  LOCAL lnstart, lcrow
  lcrow = ""
  lnstart = 1
  
  DO WHILE(lnstart <= LEN(tcref) AND !ISDIGIT(SUBSTR(tcref, lnstart)))
      lnstart = lnstart + 1
  ENDDO
  
  IF (ISDIGIT(SUBSTR(tcref, lnstart)))
      lcrow = SUBSTR(tcref, lnstart)
  ENDIF
  
  RETURN lcrow
  
  

• excel.border - Draws a Border

  LPARAMETERS tcrange, tnlinestyle, tnweight, tncolorindex, tlnotinside
  
  WITH THIS.oexcel
      .activesheet.RANGE(tcrange).SELECT
  
      LOCAL lnline
      FOR lnline = THIS.xledgeleft TO IIF(tlnotinside, THIS.xledgeright, THIS.xlinsidehorizontal)
          .activesheet.RANGE(tcrange).BORDERS(lnline).linestyle = tnlinestyle
          .activesheet.RANGE(tcrange).BORDERS(lnline).weight = tnweight
          .activesheet.RANGE(tcrange).BORDERS(lnline).colorindex = tncolorindex
      NEXT
  ENDWITH
  
  

• excel.activateworkbook

  LPARAMETERS tcwb
  
  THIS.oexcel.workbooks(tcwb).ACTIVATE()
  
  

• excel.autoformat

  LPARAMETERS tnformat
  IF EMPTY(tnformat)
      tnformat = -4154
  ENDIF
  
  THIS.oexcel.SELECTION.autoformat(tnformat)
  
  

• excel.addcomment

  LPARAMETERS tcrange, tctext
  
  LOCAL locomment
  
  WITH THIS.oexcel
  
      .activesheet.RANGE(tcrange).addcomment(tctext)
      .activesheet.RANGE(tcrange).COMMENT.VISIBLE                        = .T.
      .activesheet.RANGE(tcrange).COMMENT.SHAPE.textframe.AUTOSIZE    = .T.
  
  ENDWITH
  
  

• excel.lockrange

  LPARAMETERS tcrange, tllock
  
  THIS.oexcel.activesheet.RANGE(tcrange).locked = tllock
  
  

• excel.clearcomment

  LPARAMETERS tcrange
  
  THIS.oexcel.activesheet.RANGE(tcrange).clearcomments
  
  

• excel.getnextcolumn

  LPARAMETERS tccolumn
  * A->B, C->D, Z->AA, AZ->BA, BZ->CA ... IV
  
  LOCAL lcretval, lnasc, lc1, lc2
  
  IF LEN(tccolumn) = 1
      lc1 = ""
  ELSE
      lc1 = LEFT(tccolumn, 1)
  ENDIF
  
  lc2 = CHR(ASC(RIGHT(tccolumn, 1)) +1)
  IF lc2 > "Z"
      lc2 = "A"
  
      IF EMPTY(lc1)
          lc1 = "A"
      ELSE
          lc1 = CHR(ASC(lc1) +1)
      ENDIF
  ENDIF
  
  lcretval = lc1 + lc2
  
  RETURN lcretval
  
  

• excel.wraptext

  LPARAMETERS tcrange, tlwraptext
  
  THIS.oexcel.activesheet.COLUMNS(tcrange).wraptext = tlwraptext
  
  

• excel.setverticalalignment

  LPARAMETERS tcrange, tnalignment
  IF EMPTY(tnalignment)
      tnalignment = THIS.xltop
  ENDIF
  
  THIS.oexcel.activesheet.COLUMNS(tcrange).verticalalignment = tnalignment
  
  

• excel.setcolumnwidth

  LPARAMETERS tcrange, tnwidth
  
  THIS.oexcel.activesheet.COLUMNS(tcrange).COLUMNWIDTH = tnwidth
  
  

• excel.printselectedsheets

  THIS.oexcel.activewindow.selectedsheets.printout(1)
  
  

• excel.hiderow - used to set the hidden property to .t.. Has one parameter tnrow indicating the row to hide.

  LPARAMETERS tnrow
  
  THIS.oexcel.activesheet.ROWS(tnrow).HIDDEN = .T.
  
  

• excel.unhiderow

  LPARAMETERS tnrow
  
  THIS.oexcel.activesheet.ROWS(tnrow).HIDDEN = .F.
  
  

• excel.isrowhidden

  LPARAMETERS tnrow
  
  RETURN (THIS.oexcel.activesheet.ROWS(tnrow).HIDDEN)
  
  

Name	Initial value	Comment
onamespace	.NULL.
ooutlook	.NULL.
outlfolderinbox	6
outljournalitem	4
outlmailitem	0
outltaskitem	3

Methods

• outlook.openoutlook

  LPARAMETERS llforcenewinstance
  LOCAL llretval
  llretval = .F.
  
  WAIT WINDOW msg_openoutlook NOWAIT
  
  LOCAL lcerror, llgetobjectfailed
  lcerror = ON("ERROR")
  ON ERROR llgetobjectfailed = .T.
  
  THIS.lnewinstance=.F.
  IF !llforcenewinstance
  
      * An error occurs if outlook is currently not running.
      llgetobjectfailed = .F.
      THIS.ooutlook = GETOBJECT(,"Outlook.Application")
  
  ENDIF
  
  IF llgetobjectfailed OR llforcenewinstance
  
      * An error occurs if outlook is not installed on this machine.
      llgetobjectfailed = .F.
      THIS.ooutlook = CREATEOBJECT("Outlook.Application")
  
  ENDIF
  
  ON ERROR &lcerror
  
  WAIT CLEAR
  
  IF (TYPE("this.oOutlook")="O" AND !ISNULL(THIS.ooutlook))
  
      THIS.onamespace = THIS.ooutlook.getnamespace("MAPI")
      llretval = .T.
  ELSE
      =MESSAGEBOX(msg_outlookfailed, 16, _SCREEN.CAPTION)
      llretval = .F.
  ENDIF
  
  RETURN llretval
  
  

• outlook.closeoutlook - Leave Outlook

  IF VARTYPE(this.oOutlook)="O"
      WAIT WINDOW msg_closeoutlook NOWAIT
  
      THIS.ooutlook.QUIT()
      THIS.ooutlook=.NULL.
  
      WAIT CLEAR
  ENDIF
  
  

• outlook.addmail - Adds a new Mail Item to Outlook

  LPARAMETERS tcrecipient, tcsubject, tcbody, tcattachments, tlsavenotsent
  LOCAL lomail, lorecipient, loattachments
  
  * create new Mail Item
  lomail=THIS.ooutlook.createitem(THIS.outlmailitem)
  
  * add Recipient to the List of Recipients
  lorecipient = lomail.recipients.ADD(ALLTRIM(tcrecipient))
  
  * Check address.
  IF lorecipient.resolve()
  
      lomail.subject = ALLTRIM(tcsubject)
      lomail.body = tcbody
  
      * List of Attachments separated with |.
      IF VARTYPE(tcAttachments)="C" AND !EMPTY(tcattachments)
          lomail.body    = lomail.body + CHR(13) + CHR(13)
  
          loattachments = lomail.attachments
  
          LOCAL lcattachment, lnattachment, lnattachmentcount
          lnattachmentcount = getargcount(tcattachments, ";")
          FOR lnattachment = 1 TO lnattachmentcount
              lcattachment = getarg(tcattachments, lnattachment, ";")
              loattachments.ADD(ALLTRIM(lcattachment))
          NEXT
      ENDIF
  
      IF tlsavenotsent
          lomail.SAVE()
      ELSE
          lomail.SEND()
      ENDIF
  
  ELSE
      = MESSAGEBOX(msg_norecipient+": "+ALLTRIM(tcrecipient), 64, _SCREEN.CAPTION)
  ENDIF
  
  RETURN lomail
  
  

• outlook.getmail - Get a Mail out of Outlook by specifiying a search expression

  LPARAMETERS tcsearchexpr, tnindex
  
  * open INBOX Folder
  tnindex = 0
  
  * Example for tcSearchExpr = ".Subject = '"+lcYourSubject+"'"
  
  loitem = THIS.getnextmail(tcsearchexpr, @tnindex)
  
  RETURN loitem
  
  

• outlook.getnextmail - gets the next Mail related to the search expression previously set with getMail()

  LPARAMETER tcsearchexpr, tnindex
  
  * open INBOX Folder
  LOCAL loinboxfolder
  loinboxfolder = THIS.onamespace.getdefaultfolder(THIS.outlfolderinbox)
  
  LOCAL loitem
  loitem = .NULL.
  
  IF VARTYPE(tcSearchExpr)="C" AND !EMPTY(tcsearchexpr)
      LOCAL lnitem, lnitemcount
      lnitemcount = loinboxfolder.items.COUNT
  
      FOR lnitem = tnindex+1 TO lnitemcount
          LOCAL lo
          lo = loinboxfolder.items[lnItem]
          WITH lo
              IF (EVALUATE(tcsearchexpr))
                  loitem = lo
                  tnindex = lnitem
                  EXIT
              ENDIF
          ENDWITH
      NEXT
  ENDIF
  
  RETURN loitem
  
  

• outlook.release - Releases a FormSet or Form from memory.

  RELEASE THIS
  
  

• outlook.logon

  LPARAMETERS tcprofile, tcpassword, tlshowdialog, tlnewsession
  
  IF VARTYPE(this.oNameSpace)="O"
      THIS.onamespace.logon(tcprofile, tcpassword, tlshowdialog, tlnewsession)
  ENDIF
  
  

• outlook.logoff

  IF VARTYPE(this.oNameSpace)="O"
      THIS.onamespace.logoff()
  ENDIF
  
  

• outlook.getoutlook

  RETURN THIS.ooutlook
  
  

• outlook.addtaskitem

  LOCAL lotaskitem
  
  * create new Task Item
  lotaskitem = THIS.ooutlook.createitem(THIS.outltaskitem)
  
  RETURN lotaskitem
  
  

• outlook.addtaskrequestitem

  LOCAL lotaskitem, lcerror, llfailed, lofolder
  
  * create new Task Item
  lotaskitem = THIS.ooutlook.createitem(THIS.outltaskitem)
  
  lcerror        = ON("error")
  llfailed    = .F.
  ON ERROR llfailed = .T.
  
  lotaskitem.assign
  
  ON ERROR &lcerror
  
  IF llfailed
  
      lofolder    = THIS.onamespace.getdefaultfolder(13)
  
      lofolder.DISPLAY
  
      lotaskitem    = THIS.ooutlook.createitem(THIS.outltaskitem)
  
      lotaskitem.assign
  
  ENDIF
  
  RETURN lotaskitem
  
  

• outlook.getcurrentuser

  RETURN THIS.onamespace.currentuser.NAME
  
  

• outlook.getfolderbyname

  LPARAMETERS tcfolderlocation
  * tcFolderLocation = 'folder1;folder2;folder3'
  
  LOCAL loretval
  loretval = .NULL.
  
  tcfolderlocation = UPPER(ALLTRIM(tcfolderlocation))
  
  LOCAL loparent
  loparent = THIS.getnamespace()
  
  LOCAL lnargcount
  lnargcount = getargcount(tcfolderlocation,";")
  
  LOCAL lnarg, lcsearchfolder, llfound
  llfound = .F.
  lnarg = 1
  
  DO WHILE lnarg <= lnargcount
      llfound = .F.
      lcsearchfolder = UPPER(getarg(tcfolderlocation, lnarg, ";"))
  
      LOCAL lnnsfolder
      lnnsfoldercount = loparent.folders.COUNT
      FOR lnnsfolder = 1 TO lnnsfoldercount
          IF (lcsearchfolder == UPPER(loparent.folders.ITEM(lnnsfolder).NAME))
              lnarg = lnarg + 1
              loparent = loparent.folders.ITEM(lnnsfolder)
              llfound = .T.
              EXIT
          ENDIF
      NEXT
  
      IF !llfound
          EXIT
      ENDIF
  ENDDO
  
  IF llfound
      loretval = loparent
  ENDIF
  
  RETURN loretval
  
  

• outlook.getnamespace

  RETURN THIS.onamespace
  
  

• outlook.addmailitem

  LOCAL lomailitem
  
  * create new Mail Item
  lomailitem = THIS.ooutlook.createitem(THIS.outlmailitem)
  
  RETURN lomailitem
  
  

• outlook.addjournalitem

  LOCAL lojournalitem
  
  * create new Journal Item
  lojournalitem = THIS.ooutlook.createitem(THIS.outljournalitem)
  
  RETURN lojournalitem
  
  

Name	Initial value	Comment
^abookmarks[1,0]	.f.	Enthält alle Bookmarks eines Dokuments (wird mit der Methode ReadBookmarks gefüllt)
copendocuments	""	String aller aus der Applikation heraus geöffneten Dokumente, mit ; getrennt
lopendocument_ok	.f.	Öffnen des Dokuments erfolgreich?
ncopies	1	Anzahl zu druckende Kopien
nsavechanges	0	Änderungen speichern? 0 - nicht speichern, -1 - speichern, -2 - Frage ob speichern
oword	.NULL.	Word Objekt

Methods

• word.readbookmarks - Liesst alle im aktiven Dokument enthaltenen Bookmarks und schreibt sie in das Array aBookmarks.

  LOCAL lncountmarks, lni
  
  lncountmarks = THIS.oword.activedocument.bookmarks.COUNT
  
  DIMENSION THIS.abookmarks[lnCountMarks]
  FOR lni = 1 TO lncountmarks
      THIS.abookmarks[lni] = THIS.oword.activedocument.bookmarks(lni).NAME
  NEXT
  
  

• word.opendocument - Öffnet das angegebebe Dokument

  LPARAMETERS lcdocumenttoopen
  lcdocumenttoopen = ALLTRIM(lcdocumenttoopen)
  
  LOCAL lcerror, llopenok
  
  WAIT WINDOW lcdocumenttoopen + "..." NOWAIT
  
  lcerror  = ON("error")
  llopenok = .T.
  ON ERROR llopenok=.F.
  
  THIS.oword.documents.OPEN(lcdocumenttoopen)
  
  ON ERROR &lcerror
  
  THIS.lopendocument_ok = llopenok
  
  WAIT CLEAR
  IF !THIS.lopendocument_ok
      =MESSAGEBOX(msg_wordcannotopen+": " + lcdocumenttoopen, 64, _SCREEN.CAPTION)
  ENDIF
  
  

• word.openword - Öffnet Word

  LPARAMETERS llforcenewinstance
  
  LOCAL lcerror, llgetobjectfailed
  
  WAIT WINDOW msg_openword NOWAIT
  
  IF !llforcenewinstance
      lcerror           = ON("error")
      llgetobjectfailed = .F.
      ON ERROR llgetobjectfailed=.T.
  
      THIS.oword = GETOBJECT(, "Word.Application")
  
      ON ERROR &lcerror
  ENDIF
  
  IF llgetobjectfailed OR llforcenewinstance
      * Error handler inserted
      lcerror           = ON("error")
      llgetobjectfailed = .F.
      ON ERROR llgetobjectfailed=.T.
  
      THIS.oword = CREATEOBJECT("Word.Application")
  
      ON ERROR &lcerror
  ENDIF
  
  WAIT CLEAR
  
  * Return .T. if Word is running
  RETURN !llgetobjectfailed
  
  

• word.closedocument - Schliesst das aktive oder ein angegebenes Dokument

  LPARAMETERS lcdocumenttoclose
  LOCAL lnparameters
  lnparameters = PARAMETERS()
  
  IF !THIS.checkword(.F.)
      RETURN .F.
  ENDIF
  
  lcdocumenttoclose = IIF(lnparameters<1, THIS.oword.activedocument.NAME, ALLTRIM(lcdocumenttoclose))
  
  IF TYPE("this.oWord.Documents(lcDocumenttoClose)") = "O"
  
      IF THIS.nsavechanges = -2
  
          LOCAL lcerror, llcloseok
          llcloseok    = .T.
          lcerror  = ON("error")
  
          ON ERROR llcloseok=.F.
  
          THIS.activateword()
          THIS.oword.documents(lcdocumenttoclose).CLOSE(THIS.nsavechanges)
          THIS.setwindowstate(2)
          IF !llcloseok
              THIS.oword.documents(lcdocumenttoclose).CLOSE(0)
          ENDIF
  
          ON ERROR &lcerror
  
      ELSE
          THIS.oword.documents(lcdocumenttoclose).CLOSE(THIS.nsavechanges)
      ENDIF
  
  ENDIF
  
  

• word.setwindowstate - Setzt der Windowsstatus.

  LPARAMETERS lpn1
  lpn1 = IIF(PARAMETERS()<1, 2, lpn1)
  
  IF TYPE("this.oWord.Name") <> "U"
      THIS.oword.WINDOWSTATE = lpn1
  ENDIF
  
  

• word.editdocument - Aktiviert Word zum Bearbeiten der geöffneten Dokumente

  WITH THIS.oword
  
      .VISIBLE = .T.
      .WINDOWSTATE = 1
      .ACTIVATE()
  
      =MESSAGEBOX(msg_returntoapp, 64, _SCREEN.CAPTION)
  
      THIS.setwindowstate()
  
  ENDWITH
  
  

• word.closeword - Schliesst Word

  IF TYPE("this.oWord.Name") = "U"
      RETURN .F.
  ENDIF
  
  THIS.oword.QUIT()
  
  WAIT CLEAR
  
  

• word.saveasdocument - Wordfunktion Save As

  LPARAMETERS tcsaveas, tlpromptforsaveproperties, tnfileformat
  IF PARAMETERS() < 1
      tcsaveas = "X"+SUBSTR(SYS(2015),4,7)
  ENDIF
  
  WITH THIS.oword
      LOCAL llsavepropertiesprompt
      * save SavePropertiesPrompt
      llsavepropertiesprompt = .options.savepropertiesprompt
      * set SavePropertiesPrompt
      .options.savepropertiesprompt = tlpromptforsaveproperties
  
      IF EMPTY(tnfileformat)
          .wordbasic.filesaveas(tcsaveas)
      ELSE
          .wordbasic.filesaveas(tcsaveas, tnfileformat)
      ENDIF
  
      * restore SavePropertiesPrompt
      .options.savepropertiesprompt = llsavepropertiesprompt
  ENDWITH
  
  RETURN (tcsaveas)
  
  

• word.inserttext - Schreibt den angegebenen Text an der aktuellen Cursorposition

  LPARAMETERS lctext
  
  THIS.oword.SELECTION.TEXT = lctext
  
  

• word.gotobookmark - Springt das angegebene Bookmark an

  LPARAMETERS lcbookmark
  
  THIS.oword.SELECTION.GOTO(-1, , , lcbookmark)
  
  

• word.printdocument - Druckt das aktive oder angegebene Worddokument

  LPARAMETERS tlupdatefieldsatprint
  
  IF !THIS.checkword(.T.)
      RETURN .F.
  ENDIF
  
  THIS.oword.VISIBLE = .T.
  
  WAIT WINDOW THIS.oword.activedocument.NAME + " "+msg_wordprinting NOWAIT
  
  WITH THIS.oword
      LOCAL lloldupdatefieldsatprint
      lloldupdatefieldsatprint = .options.updatefieldsatprint
  
      .options.updatefieldsatprint = tlupdatefieldsatprint
  
      .wordbasic.fileprint(1)
  
      .options.updatefieldsatprint = lloldupdatefieldsatprint
  ENDWITH
  
  WAIT CLEAR
  
  

• word.gotopofdocument - Geht an den Anfang des aktiven Dokuments

  LOCAL lcerror
  
  lcerror = ON("error")
  ON ERROR x = .T.
  
  THIS.oword.SELECTION.homekey(6)
  
  ON ERROR &lcerror
  
  
  

• word.tab - Simuliert die Tabtaste

  THIS.oword.SELECTION.moveright(12)
  
  

• word.insertsymbol - Schreibt ein Symbol an die aktuelle Cursorpoition. Funktioniert leider nicht!

  lparameters lnsymbol, lcfont, llunicode
  
  

• word.insertformtext - Weisst einem Formtext Objekt den angegebenen Text zu

  LPARAMETERS lcname, lctext
  
  THIS.oword.activedocument.formfields(lcname).result = lctext
  
  

• word.closealldocuments - Schliesst alle offenen Dokumente

  IF !THIS.checkword(.F.)
      RETURN .F.
  ENDIF
  
  THIS.oword.documents.CLOSE(THIS.nsavechanges)
  
  

• word.printalldocuments - Druckt alle offenen Dokumente

  IF !THIS.checkword(.T.)
      RETURN .F.
  ENDIF
  
  LOCAL lni
  
  WITH THIS
  
      FOR lni = 1 TO .oword.documents.COUNT
  
          .activatedocument(.oword.DOCUMENT(lni).NAME)
          .printdocument()
  
      ENDFOR
  
      .activatedocument(.oword.DOCUMENT(1).NAME)
  
  ENDWITH
  
  

• word.closemydocuments - Schliesst alle im String opendocuments enthaltenen Dokumente

  IF !THIS.checkword(.F.)
      RETURN .F.
  ENDIF
  
  LOCAL lni, lcdocumenttoclose
  
  WITH THIS
  
      lni               = 1
      lcdocumenttoclose = getarg(.copendocuments, lni)
      DO WHILE !EMPTY(lcdocumenttoclose)
  
          .closedocument(lcdocumenttoclose)
  
          lni               = lni +1
          lcdocumenttoclose = getarg(.copendocuments, lni)
  
      ENDDO
  
  ENDWITH
  
  

• word.printmydocuments - Druckt alle im String opendocuments enthaltenen Dokumente

  IF !THIS.checkword(.T.)
      RETURN .F.
  ENDIF
  
  LOCAL lni, lcdocumenttoprint
  
  WITH THIS
  
      lni               = 1
      lcdocumenttoprint = getarg(.copendocuments, lni)
      DO WHILE !EMPTY(lcdocumenttoprint)
  
          IF .activatedocument(lcdocumenttoprint)
              .printdocument()
          ENDIF
  
          lni               = lni +1
          lcdocumenttoprint = getarg(.copendocuments, lni)
  
      ENDDO
  
      .activatedocument(getarg(.copendocuments, 1))
  
  ENDWITH
  
  

• word.checkword - Prüft ob Word aktiv ist und mindestens ein Dokument geöffnet ist

  LPARAMETERS tlgetmessage
  
  IF TYPE("this.oWord.Name") <> "U" AND THIS.oword.documents.COUNT > 0
  
      RETURN .T.
  
  ELSE
  
      IF tlgetmessage
          =MESSAGEBOX(msg_wordnotrunning, 64, _SCREEN.CAPTION)
      ENDIF
      RETURN .F.
  
  ENDIF
  
  

• word.openasdocument

  LPARAMETERS lcdocumenttoopen
  lcdocumenttoopen = ALLTRIM(lcdocumenttoopen)
  
  LOCAL lcerror, llopenok
  
  WAIT WINDOW lcdocumenttoopen + " "+msg_opendoc NOWAIT
  
  lcerror  = ON("error")
  llopenok = .T.
  ON ERROR llopenok=.F.
  
  THIS.oword.documents.openasdocument(lcdocumenttoopen)
  
  ON ERROR &lcerror
  
  THIS.lopendocument_ok = llopenok
  
  WAIT CLEAR
  IF !THIS.lopendocument_ok
      =MESSAGEBOX(msg_wordcannotopen+": " + lcdocumenttoopen, 64, _SCREEN.CAPTION)
  ENDIF
  
  

• word.adddocument - Erstellt ein neues Dokument

  LPARAMETERS lctemplate
  lctemplate = IIF(PARAMETERS()<1,"",ALLTRIM(lctemplate))
  
  LOCAL lcerror, llopenok
  
  lcerror  = ON("error")
  llopenok = .T.
  ON ERROR llopenok=.F.
  
  THIS.oword.documents.ADD(lctemplate)
  
  ON ERROR &lcerror
  
  THIS.lopendocument_ok = llopenok
  
  IF !THIS.lopendocument_ok
      =MESSAGEBOX(msg_wordcannotopen+": " + lctemplate, 64, _SCREEN.CAPTION)
  
      RETURN ""
  
  ELSE
  
      RETURN THIS.oword.activedocument.NAME
  
  ENDIF
  
  

• word.activatedocument - Macht das angegebene Dokument zum aktiven Dokument

  LPARAMETERS lcdocumenttoactivate
  lcdocumenttoavtivate = ALLTRIM(lcdocumenttoactivate)
  
  IF TYPE("this.oWord.Documents(lcDocumenttoActivate)") = "O"
      THIS.oword.documents(lcdocumenttoactivate).ACTIVATE()
      RETURN .T.
  ELSE
      =MESSAGEBOX(msg_wordcannotactivate+": " + TRIM(lcdocumenttoactivate), 64, _SCREEN.CAPTION)
      RETURN .F.
  ENDIF
  
  

• word.insertautotext

  LPARAMETERS lcautotext
  
  THIS.oword.activedocument.attachedtemplate.autotextentries(lcautotext).INSERT(THIS.oword.SELECTION.RANGE, .T.)
  
  

• word.deleteselection

  LPARAMETERS tnunit, tncount
  IF EMPTY(tnunit)
      tnunit = 1
  ENDIF
  IF EMPTY(tncount)
      tncount = 1
  ENDIF
  
  THIS.oword.SELECTION.DELETE(tnunit, tncount)
  
  

• word.updatefield

  LPARAMETERS tcbookmark
  
  WITH THIS.oword
      .SELECTION.GOTO(-1, , , tcbookmark)
      .SELECTION.FIELDS.UPDATE
  ENDWITH
  
  

• word.setvisible

  LPARAMETERS tlvisible
  tlvisible = IIF(PARAMETERS()<1, .T., tlvisible)
  
  THIS.oword.VISIBLE = tlvisible
  
  

• word.mailmerge

  LPARAMETERS tnmaindacumenttype, tcfilename, tlsuppress
  tlsuppress = IIF(PARAMETERS()<3,.T.,tlsuppress)
  
  WITH THIS.oword
  
      .activedocument.mailmerge.maindocumenttype = tnmaindacumenttype
  
      IF tnmaindacumenttype <> -1
  
          .wordbasic.mailmergeopendatasource(tcfilename, 0, 0, 1, 0, "", "", 0, "", "", "Entire Spreadsheet", "", "")
          .wordbasic.mailmerge(1, 0, 0, "", "", 0)
  
      ENDIF
  
      .activedocument.mailmerge.suppressblanklines = tlsuppress
  
  ENDWITH
  
  

• word.gobottomofdocument

  LOCAL lcerror
  
  lcerror = ON("error")
  ON ERROR x = .T.
  
  THIS.oword.SELECTION.endkey(6)
  
  ON ERROR &lcerror
  
  

• word.viewmergefieldcodes

  LPARAMETERS tlview
  
  THIS.oword.activedocument.mailmerge.viewmailmergefieldcodes = tlview
  
  

• word.suppressblanklines

  LPARAMETERS tlsuppress
  tlsuppress = IIF(PARAMETERS()<1, .T., tlsuppress)
  
  THIS.oword.activedocument.mailmerge.suppressblanklines = tlsuppress
  
  

• word.checkdocument

  LPARAMETERS tcdocumenttocheck, tlgetmessage
  
  IF TYPE("this.oWord.Documents(tcDocumenttoCheck)") = "O"
      RETURN .T.
  ELSE
      IF tlgetmessage
          =MESSAGEBOX(msg_worddocnotopen+": " + TRIM(tcdocumenttocheck), 64, _SCREEN.CAPTION)
      ENDIF
      RETURN .F.
  ENDIF
  
  

• word.mergetoprinter

  IF !THIS.checkword(.T.)
      RETURN .F.
  ENDIF
  
  WAIT WINDOW THIS.oword.activedocument.NAME + " "+msg_wordprinting NOWAIT
  
  WITH THIS.oword.activedocument.mailmerge
  
      LOCAL lcerror, llcloseok
      llcloseok    = .T.
      lcerror  = ON("error")
  
      ON ERROR llcloseok=.F.
  
      .destination = 1
      .execute()
  
      ON ERROR &lcerror
  
  ENDWITH
  
  

• word.deletebookmark

  LPARAMETERS tcbookmark
  IF EMPTY(tnunit)
      tnunit = 1
  ENDIF
  IF EMPTY(tncount)
      tncount = 1
  ENDIF
  
  THIS.oword.activedocument.bookmarks(tcbookmark).DELETE
  
  

• word.deletebookmark2

  LPARAMETERS tcbookmark
  THIS.oword.activedocument.bookmarks(tcbookmark).SELECT
  THIS.oword.SELECTION.homekey(5)
  THIS.oword.SELECTION.endkey(5, 1)
  THIS.oword.SELECTION.DELETE(1, 1)
  
  

• word.activateword

  WITH THIS.oword
  
      .VISIBLE = .T.
      .WINDOWSTATE = 1
      .ACTIVATE()
  
  ENDWITH
  
  

• word.updatedocument

  IF !THIS.checkword(.T.)
      RETURN .F.
  ENDIF
  
  WITH THIS.oword
  
      .SELECTION.wholestory
      .SELECTION.FIELDS.UPDATE
  
  ENDWITH
  
  

• word.paste

  IF !THIS.checkword(.T.)
      RETURN .F.
  ENDIF
  
  LOCAL lcerror
  
  lcerror = ON("error")
  ON ERROR x = .T.
  
  THIS.oword.SELECTION.paste()
  
  ON ERROR &lcerror
  
  

• word.pagetray

  LPARAMETERS tcdocument, tnfirstpagetray, tnotherpagetray
  
  IF !THIS.checkword(.F.)
      RETURN .F.
  ENDIF
  
  IF EMPTY(tcdocument)
      tcdocument        = THIS.oword.activedocument.NAME
  ENDIF
  IF EMPTY(tnfirstpagetray)
      tnfirstpagetray    = 0
  ENDIF
  IF EMPTY(tnotherpagetray)
      tnotherpagetray    = 0
  ENDIF
  
  IF TYPE("this.oWord.Documents(tcDocument)") = "O"
  
      WITH THIS.oword.documents(tcdocument).pagesetup
          .firstpagetray = tnfirstpagetray
          .otherpagestray = tnotherpagetray
      ENDWITH
  
  ENDIF
  
  

• word.deletecells

  THIS.oword.SELECTION.cells.DELETE(2)
  
  

• word.addfootnote - Adds a footnote . Parameters are tcfootnote, tctext, tlnoseparator, tcreferencefont, tnreferencesize, tctextfont, tntextsize

  LPARAMETERS tcfootnote, tctext, tlnoseparator, tcreferencefont, tnreferencesize, tctextfont, tntextsize
  
  WITH THIS.oword
  
      .activedocument.footnotes.ADD(.SELECTION.RANGE, tcfootnote, tctext)
  
      IF tlnoseparator
          .activedocument.footnotes.SEPARATOR.DELETE
      ENDIF
  
      IF !EMPTY(tcreferencefont)
          .activedocument.footnotes(.activedocument.footnotes.COUNT).REFERENCE.FONT.NAME = tcreferencename
      ENDIF
      IF !EMPTY(tnreferencesize)
          .activedocument.footnotes(.activedocument.footnotes.COUNT).REFERENCE.FONT.SIZE = tnreferencesize
      ENDIF
      IF !EMPTY(tctextfont)
          .activedocument.footnotes(.activedocument.footnotes.COUNT).RANGE.FONT.NAME = tctextfont
      ENDIF
      IF !EMPTY(tntextsize)
          .activedocument.footnotes(.activedocument.footnotes.COUNT).RANGE.FONT.SIZE = tntextsize
      ENDIF
  
  ENDWITH
  
  

• word.countfootnotes - Counts the existing footnotes in the defined section. Parameter tnsection defines the section.

  LPARAMETERS tnsection
  
  RETURN (THIS.oword.activedocument.sections(tnsection).RANGE.footnotes.COUNT)
  
  

• word.insertcrossreference - Creates a new cross reference. Parameters are tnreferencetype, tnreferencekind, tcreferenceitem, tlinsertashyperlink, tlincludeposition

  LPARAMETERS tnreferencetype, tnreferencekind, tcreferenceitem, tlinsertashyperlink, tlincludeposition
  
  WITH THIS.oword
  
      .SELECTION.insertcrossreference(tnreferencetype, tnreferencekind, tcreferenceitem, ;
          tlinsertashyperlink, tlincludeposition)
  
  ENDWITH
  
  

• word.savedocument

  LPARAMETERS tlforcesave
  
  IF !THIS.checkword(.F.)
      RETURN .F.
  ENDIF
  
  LOCAL llret
  
  WITH THIS.oword
  
      IF THIS.checkdocument(.activedocument)
  
          *-- sicherstellen, dass auch wirklich gespeichert wird
          IF tlforcesave
              .SELECTION.typetext(" ")
              .SELECTION.typebackspace
          ENDIF
  
          .activedocument.SAVE()
  
          llret = .T.
  
      ELSE
  
          llret = .F.
  
      ENDIF
  
  ENDWITH
  
  RETURN (llret)